Transmission de données dans autre tableau

Bonjour à toutes et à tous. J'ai un fichier retard avec un formulaire. les données se mettent dans le tableau données. Je n'arrive pas retranscrire les données du premier tableau, dans un second en fonction du nom.

Si quelqu'un pouvait m'aider à trouver une solution, je l'en remercie d'avance.

Bonne soirée.

Bonjour,

Votre code modifié:

Private Sub valider_Click()
    Dim dl As Long, Jour As Long, Heure
    Dim Agent As String, Rc As String
    Dim Avertissement As Boolean, Bulletin As Boolean
    Dim Sh_Agent As Worksheet

    With Sheets("donnees")
        With .ListObjects("Tableau1")
            If .ListRows.Count = 0 Then  'définit la dernière ligne du tableau
                .ListRows.Add: dl = 1
            Else:
                .ListRows.Add: dl = .ListRows.Count 'insérer à la dernière ligne
            End If

            With .DataBodyRange 'inscrit les données
                Agent = Me.ComboBox1.Text 'Agent
                Mois = Me.mois1.Text 'mois
                Jour = Me.jour1.Text 'jour
                Heure = Me.TextBox1.Text 'Heure
                Avertissement = Me.CheckBox1 'Avertissement oral
                Bulletin = Me.CheckBox2 'Bulletin de retard
                Rc = Me.TextBox2.Text 'RC déduit
               .Item(dl, 1) = Agent
               .Item(dl, 2) = Jour 'jour
               .Item(dl, 3) = Mois 'mois
               .Item(dl, 4) = Heure 'Heure
               .Item(dl, 5) = Avertissement 'Avertissement oral
               .Item(dl, 6) = Bulletin 'Bulletin de retard
               .Item(dl, 7) = Rc 'RC déduit
            End With

            With .Sort  'tri de A à Z en fonction de la colonne Noms
               .SortFields.Clear
               .SortFields.Add Key:=Range("Tableau1[[#All],[noms]]"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortTextAsNumbers
               .Header = xlYes
               .MatchCase = False
               .Orientation = xlTopToBottom
               .SortMethod = xlPinYin
               .Apply
            End With
        End With

        Set Sh_Agent = Sheets(Agent) 'feuille de l'agent concerné
        'on recherche la colonne du  mois et la ligne du jour
        m = Application.Match(Mois, Sh_Agent.Rows(3), 0)
        j = Jour + 4
        Sh_Agent.Cells(j, m + 1) = Heure
        Sh_Agent.Cells(j, m + 2) = Avertissement
        Sh_Agent.Cells(j, m + 3) = Bulletin
        Sh_Agent.Cells(j, m + 4) = Rc

        ComboBox1.Text = ""
        jour1.Text = ""
        mois1.Text = ""
        TextBox1 = ""
        CheckBox1 = ""
        CheckBox2 = ""
        TextBox2 = ""
    End With
End Sub

Cdlt

Bonjour,

Merci beaucoup, grâce à ce code mon projet se termine. Encore merci

Cdt