Utilisation Nb.Si avec une recherche X
Bonjour,
J'ai un fichier excel pour un classement e-sport, je bloque sur une formule qui me permettrai de compter le nombre de podium de chaque pilotes.
J'ai un onglet "Classement Pilotes" ou se trouve ma colonne podium, le classement est dynamique donc l'ordre des pilotes n'est pas fixe.
Il faut donc que le nom du pilote indiqué de C11 à C30 aille chercher dans l'onglet résultat le nom du pilote de A9 à A28 et ensuite recherche dans la ligne correspondante de C9 à X9 pour mon pilote 1 à C28 à X28 pour mon pilote 20, le nombre de fois ou le nombre est supérieur ou égale à 15 qui correspond à une place sur le podium et reporter ce résultat dans ma colonne podium de l'onglet "Classement Pilotes".
j'ai essayé pas mal de chose sans succès.
=SI(ESTERREUR(RECHERCHEV(A11;Résultats!$AJ$9:$AN$60;4;0));"-";RECHERCHEV(A11;Résultats!$AJ$9:$AN$60;4;0))
=NB.SI(RECHERCHEV(A11;Résultats!$AJ$9:$AN$60;C28:X28;">=15");RECHERCHEV(A11;Résultats!$AJ$9:$AN$60;C28:X28;">=15";0))
=NB.SI(RECHERCHEV(C11:C30; Résultats!A9:X28; EQUIV(">=15";Résultats!A8:X8;0); 0); "<>0")
=SOMMEPROD((RECHERCHEV(C11:C30; Résultats!A9:X28; EQUIV("Résultats!A27:X27"; Résultats!A27:X27; 0); 0) >= 15) * 1)
Si quelqu'un a une idée je suis preneur...
merci, le fichier est trop lourd pour le mettre en PJ :(
Bonjour,
le fichier est trop lourd pour le mettre en PJ
On ne vous demande pas le fichier dans son intégralité, mais un échantillon représentatif, exempt de données confidentielles, parce que, entre l'énoncé du problème et l'analyse de vos formules, on ne comprend pas. Qu'est-ce qu'il y a dans cette zone "Résultats!$AJ$9:$AN$60"?
Cdlt
J'ai pu alléger le fichier en enlevant les images. y'a rien de confidentiel, j'ai avancé un peu. j'ai un résultat mais qui ne correspond pas au résultat attendu.
Le but du jeux dans l'onglet "Classement pilotes" colonne G "Podium", c'est de retrouver le nombre de podium de chaques pilotes en s'appuyant sur son nom en colonne C et faisant référence à l'onglet "Résultats".
Les point marqués pour chaque GP y sont indiqués, un podium correspond à supérieur ou égale à 15 points. si pas de podium j'aimerais avoir un tiret en résultat.
En résultat j'obtiens un podium de plus et si pas de résultat un 1.
Je mets le fichier en PJ.
Merci pour votre aide.
Bonjour,
Si j'ai bien compris, en G11:
=SI(SOMMEPROD((Résultats!$A$9:$A$28=C11)*(Résultats!$C$9:$X$28>=15))>0;SOMMEPROD((Résultats!$A$9:$A$28=C11)*(Résultats!$C$9:$X$28>=15));"-")à étirer vers le bas
Cdlt
Bonjour à tous !
Une autre approche ?
Formule unique et dynamique en G11 :
=LET(c;MAP(C11:C30;LAMBDA(r;NB.SI.ENS(RECHERCHEX(r;Résultats!A9:A28;Résultats!C9:AF28;"--";0);">=15")));SI(c;c;"-"))Les plages sont à adapter. L'utilisation des tableaux structurés serait une opportunité.
Bonjour,
Encore une variation :)
Si j'ai bien compris j'écrirai ainsi la formule en G11:
=SOMME((Résultats!$A$9:$A$28='Classements Pilotes'!C11)*(Résultats!$C$9:$AF$28>=15))formule qu'il convient de tirer vers le bas en l'absence de tableau structuré (il faut vraiment les utiliser)
l'astuce consiste à créer une première matrice d'une colonne contenant l'emplacement de ton pilote et à la multiplier par une matrice contenant l'emplacement des scores supérieur ou égale à 15
enfin la somme de ce calcul t'indique le nombre de fois où tes conditions sont réunis simultannément
Edit : c'est la même solution que Arturo83 désolé ^^;
Bonjour,
Un grand merci pour votre aide.
Ca fonctionne parfaitement :)
Bonjour à tous de nouveau !
Merveilleux.....
Je vous remercie de ce retour.