Compter le nombre de cellules filtrées sans doublon
BOnjour
J'ai une colonne de chiffre de contract exemple : 45896,48596,47589,48596 je veux etre capable de compter combien j'ai de cellule total sans les doublons et pouvoir l'utiliser avec un filtre automatique. La fonction NB.DIFF fonctionne mais je ne peux pas l'utiliser avec le filtre automatique. Est-ce que quelqu'un a une solution?
Meric
Nathalie
Bonjour,
En cherchant sur ce forum "compter sans doublon" tu auras plein de réponses, par exemple :
=SOMMEPROD(1/NB.SI(A2:A5;A2:A5))
Tu remplaces A2:A5 par la plage de tes valeurs (ne pas prendre le titre de la colonne).
A+
dachevid a écrit :Bonjour,
En cherchant sur ce forum "compter sans doublon" tu auras plein de réponses, par exemple :
=SOMMEPROD(1/NB.SI(A2:A5;A2:A5))
Tu remplaces A2:A5 par la plage de tes valeurs (ne pas prendre le titre de la colonne).
A+
Parfait pour la formule mais mon autre probleme c'est quand je veux exécuter un filtre automatique il ne compte pas le filtre mais la totalité
Merci de m'aider
Bonjour
Exemple
tes données sont de C2 à C100
matricielle à valider avec les 3 touches Ctrl+Maj+Entrée
=SOMME((FREQUENCE(SI(C2:C100="";"";SI(SOUS.TOTAL(3;DECALER(C2;LIGNE(C2:C100)-LIGNE(C2);));EQUIV(C2:C100;C2:C100;0)));LIGNE(C1:C100))>0)*1)Fichier exemple joint
Cordialement
Bonjour
Désolée mais que veux dire valider avec les 3 touches Ctrl+Maj+Entrée?
MErci de m'aider
Valider : Appuyer simultanément sur...
Voici mon fichier.
Merci
Nathalie
-- 01 Nov 2010, 14:41 --
Ca fonctionne un gros merci a vous tous.
Nathalie
Ca fonctionne mais pas normalement j'ai des cellules qui ne compte pas alors mon total est pas bon parfois.
Quelqu'un peu maider?
Merci
Nathalie
Bonjour
Rappel: Les formules matricielles sont entrées en:
- Plaçant le curseur de la souris dans la barre de formule, puis,
appuyer simultanément sur Ctrl+Maj+Entrée.
excel place la formule entre accolades (pas vous)
Le fichier
Cordialement
Bonjour
Oui j'ai bien fait le ctrl shift et entrer. Mais il semble y avoir un problème il ne compte pas toutes les cellules car je n'arrive pas au bon nombre on dirait qu'il saute des cellules. Je vous envoi mon fichier pour tester dans la cellule B3 il compte le nombre de contrat non identique avec un filtre sur les vendeurs donc par vendeur.
Merci de m'aider.
Nathalie
Bonjour
Un peu d'attention...
Remplace dans la formule le dernier B6 par B1
=SOMME((FREQUENCE(SI(B6:B500="";"";SI(SOUS.TOTAL(3;DECALER(B6;LIGNE(B6:B500)-LIGNE(B6);));EQUIV(B6:B500;B6:B500;0)));LIGNE(B6:B500))>0)*1)
est mauvais, tu dois avoir
=SOMME((FREQUENCE(SI(B6:B500="";"";SI(SOUS.TOTAL(3;DECALER(B6;LIGNE(B6:B500)-LIGNE(B6);));EQUIV(B6:B500;B6:B500;0)));LIGNE(B1:B500))>0)*1)
et n'oublie pas de revalider ensuite avec Ctrl+Maj+entrée
(on va y arriver..)
Cordialement
Un gros merci ca fonctionne mais je ne comprend pas le B1 ?
Merci
Nathalie
Ca fonctionne super bien un gros merci
Nathalie