Etirer une formule et la décaler de 7 et non de 1
Bonjour,
Je n'ai pas utilisé les bons mots clés et je n'arrive pas à trouver la réponse d'un sujet qui a déjà dû être traité !
Je veux décaler une formule de 7 lignes et non pas de 1 en l'étirant ...
Une feuille ya une ligne par jour de semaine
Une seconde feuille fait le total des 7 lignes de la semaine
J'ai pensé au tableau croisé dynamique le problème c'est qu'il faut l'actualiser pour qu'il se mette alors que la formule non.
Je peux bien écrire mes 52 formules à la main, mais bon ! :)
L'exemple est en pièce jointe comment étirer pour que les formules fassent :
=SOMME('Horaires 2023'!H3:H9)
=SOMME('Horaires 2023'!H10:H16)
=SOMME('Horaires 2023'!H17:H23)
etc
Merci !!
Bonjour,
Essayez ceci:
=SOMME(INDIRECT("'Horaires 2023'!H"&LIGNE()*7-4&":H"& LIGNE()*7+2))Cdlt
Bonjour
Une solution en mettant cette formule en B2 de la feuille 3. Ensuite tirer la formule vers les bas
=SOMME(DECALER('Horaires 2023'!H$2;(LIGNE()-1)*7;;7))
Crdlt
Bonjour à tous !
Une autre approche ?
=SOMME(FILTRE('Horaires 2023'!$H$2:$H$366;NO.SEMAINE.ISO('Horaires 2023'!$A$2:$A$366)=SUBSTITUE(A1;"semaine";"")*1))Et pour Microsoft 365 (une formule unique et dynamique) :
=LET(
s;SEQUENCE(52);
h;'Horaires 2023'!H2:H366;
d;'Horaires 2023'!$A$2:$A$366;
BYROW(s;LAMBDA(r;SOMME(FILTRE(h;NO.SEMAINE.ISO(d)=r))))
)Bonjour, Merci beaucoup pour vos réponses rapides, c'est super, il y a pleins de possibilité de le faire, le tout c'est de savoir imbriquer les formules, génial ! J'ai pris celle ci qui est toute simple et fait parfaitement le boulot :
=SOMME(DECALER('Feuilxx'!H$2;(LIGNE()-1)*7;;7))
Merci encore, bonne journée !!
Bonjour à tous de nouveau !
Fort bien
Je vous remercie de ce retour.
Merci de préciser, dans votre profil, la nature de votre Excel ( 2019 ? 2021 ? 365 ? ...) ( "récente" est une notion très ambiguë....)
Hi hi c'est fait, j'avais pas cette infos sous la main lorsque j'avais créé le profil. Chose résolue ! bonne journée
Bonjour à tous de nouveau !
Merci !
Pour Microsoft 365, une formule unique et dynamique :
=LET(
s;SEQUENCE(52);
h;'Horaires 2023'!H2:H366;
d;'Horaires 2023'!$A$2:$A$366;
BYROW(s;LAMBDA(r;SOMME(FILTRE(h;NO.SEMAINE.ISO(d)=r))))
)