Dimanche qui sont un 1er mai, 25 décembre ou 1er janvier entre 2 dates

Bonjour toutes et tous,

Est il possible par formule de compter les dimanche qui sont un 1er mai, 25 décembre ou 1er janvier entre 2 dates

Les dates bornes peuvent être sur plusieurs années

Merci

Très cordialement

Hugues

Bonsoir à tous !

Une proposition ?

=LET(
m_j;{"2512";"0101";"0105"};
m_d;SEQUENCE(D5-D4+1;;D4);
NB(FILTRE(m_d;(ESTNUM(EQUIVX(TEXTE(m_d;"jjmm");m_j;0)*(JOURSEM(m_d;2)=7)))))
)

Avec :
D4 : date début
D5 : date fin

Bonsoir à tous ,

Étant donné que vous utilisez Excel 2016, une proposition de formule (par exemple pour le 1er janvier) :

=SOMMEPROD(--(DATE(LIGNE(INDIRECT(ANNEE($A2)&":"&(ANNEE($B2)+1)));1;1)>=$A2)*(DATE(LIGNE(INDIRECT(ANNEE($A2)&":"&(ANNEE($B2)+1)));1;1)<=$B2)*(JOURSEM(DATE(LIGNE(INDIRECT(ANNEE($A2)&":"&(ANNEE($B2)+1)));1;1))=1))

Je ne possède plus qu' Office 365 donc je n'ai pas pu vérifier s'il faut valider ou non cette formule matriciellement (par la combinaison des trois touches Ctrl+Maj+Entrée).

Malgré la présence de SommeProd, je pense qu'il faut une validation matricielle (Pomme+Shift+Entrée) . A vous de tester...

Bonjour,
@JFL
As-tu testé ta formule ?
Une autre proposition basée sur ton exemple de jours fériés.
Cdlt.

=LET(jf;{"0101";"0105";"2512"};n;NB.JOURS.OUVRES.INTL(C2;C3;"1111110");dim;SERIE.JOUR.OUVRE.INTL(C2-1;SEQUENCE(n);"1111110");NB(EQUIVX(TEXTE(dim;"jjmm");jf)))

Re,

Une formule plus simple qui compte tout en maintenant (pour toutes versions d'Excel).

La formule nécessite peut-être une validation matricielle (pas vérifiable avec ma version O365).

La formule en C2 :

=SOMMEPROD((ESTNUM(EQUIV(TEXTE((A2+(LIGNE(INDIRECT("1:" & (B2-A2+1)))-1));"jj/mm");{"01/01";"01/05";"25/12"};0)))*(JOURSEM((A2+(LIGNE(INDIRECT("1:" & (B2-A2+1)))-1)))=1))

Bonjour Toutes et Tous,

JLF, mafraise, Jean-Eric merci à vous 3 de vos retours.

mafraise et Jean-Eric vos 2 approches fonctionnent merci d'avoir résolu ma demande

Trés cordialement

Hugues

Bonjour à tous

Une variante si cela peut encore intéresser...

Bye !

Bonjour à tous !

Jean-Eric a écrit :

@JFL
As-tu testé ta formule ?

Oui mais.... pas suffisamment visiblement !

Parenthèses superfétatoires éliminées :

=LET(
m_j;{"2512";"0101";"0105"};
m_d;SEQUENCE(D5-D4+1;;D4);
NB(FILTRE(m_d;ESTNUM(EQUIVX(TEXTE(m_d;"jjmm");m_j;0))*(JOURSEM(m_d;2)=7)))
)