Macro envoie d'un mail par Gmail avec PJ

Bonjour,

Je souhaite une macro pour envoyer un mail via Gmail avec en pièce jointe une partie d'un tableau en pdf.

merci

Bonsoir bettina,

Vous pouvez essayer d'utiliser ceci

' *** ATTENTION !
' ***Il faut activer la référence : Microsoft CDO for Windows 2000 Library
Sub email_pdf()
  Dim sDos As String, sNomPDF As String
  Dim Cdo_Msg As New Cdo.Message
  '
  sDos = "C:\Temp\"
  ' Création du fichier PDF
  sNomPDF = "Nom Du Fichier.pdf"
  ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=sDos & sNomPDF, _
    Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

  With Cdo_Msg
    'configuration message
    With .Configuration
      .Fields(cdoSMTPServer) = "smtp.gmail.com"
      .Fields(cdoSMTPConnectionTimeout) = 60
      .Fields(cdoSendUsingMethod) = cdoSendUsingPort
      .Fields(cdoSMTPServerPort) = 465
      .Fields(cdoSMTPAuthenticate) = cdoBasic
      .Fields(cdoSMTPUseSSL) = True
      .Fields(cdoSendUserName) = "xxxxxxxxxx@gmail.com"
      ' Validation en 2 étapes activée
      ' https://myaccount.google.com/signinoptions/two-step-verification
      ' Tout en bas : Mot de passe pour application
      .Fields(cdoSendPassword) = "MonMotDePassePourApplication"
      .Fields.Update
    End With
    .To = "destinataire@gmail.com"
    .From = "adressefrom"
    .CC = ""
    .BCC = ""
    .Subject = "Sujet du mail"
    .TextBody = "Texte du mail"
    .AddAttachment (sDos & sNomPDF)
    .Send
  End With
  Set Cdo_Msg = Nothing
End Sub

Mais je ne sais pas s'il fonctionne correctement

A+