Envoi plage de cellules d'une feuille Excel par mail en renommant le fichie
E
Bonjour à tous.
Dans le fichier ci-joint, je parviens à envoyer une feuille de mon classeur excel via outlook. Mais je rencontre deux petits soucis : j'aimerai envoyer uniquement les cellules A01:H35 dans un fichier excel et je souhaiterai que le fichier envoyé porte le nom de la cellule B3.
D'avance merci et bonne journée !
Dans le fichier ci-joint, je parviens à envoyer une feuille de mon classeur excel via outlook. Mais je rencontre deux petits soucis : j'aimerai envoyer uniquement les cellules A01:H35 dans un fichier excel et je souhaiterai que le fichier envoyé porte le nom de la cellule B3.
D'avance merci et bonne journée !
Bonjour Elgominos,
voici un exemple à tester
Sub testElgominos()
'https://forum.excel-pratique.com/excel/envoi-plage-de-cellules-d-une-feuille-excel-par-mail-en-renommant-le-fichie-181065
Dim OutApp As Object, OutMail As Object
Dim Filename As String
Dim Wb As Workbook
Dim Source As Range, Dest As Range
Application.ScreenUpdating = False
With Sheets("BCI")
Set Source = .Range("A1:H35")
Filename = Environ$("temp") & "\" & .Range("B3") & ".xlsx"
End With
Set Wb = Workbooks.Add(xlWBATWorksheet)
Set Dest = Wb.Sheets(1).Range("A1")
Source.Copy
Dest.PasteSpecial xlPasteColumnWidths
Dest.PasteSpecial xlPasteAll
With Wb
.SaveAs Filename
.Close
End With
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
On Error Resume Next
With OutMail
.to = "test@mail.fr"
.CC = ""
.BCC = ""
.Subject = "test"
.Body = "Bonjour, blablabla"
.Attachments.Add Filename
.Display 'ou .Send
' .Send
End With
On Error GoTo 0
Kill Filename
End SubE
Bonjour.
Cela fonctionne à merveille !
Merci beraucoup.