Fonction Index+Equiv et nom de colonne

Bonjour,

Je dispose d'un tableau dans lequel j'ai des informations de secteur en ligne et les années en colonnes (Feuille 1) qui renvoie une valeur loyer.

Sur mon autre feuille, je dispose d'information de bail, j'ai deux colonnes qui concernent le secteur & l'année (Feuille 2)

L'année est récupérée par une formule d'une autre colonne qui donne la date d'effet du bail.

=ANNEE(Q2)

Problème : Je fais un INDEX+EQUIV pour récupérer depuis mon tableau Feuille 1 la valeur loyer qui correspond a mes deux variables (secteur + année) sauf qu'il y a un soucis avec l'année.

La formule ça donne ça :

=INDEX(Tableau1[[2015]:[2022]];EQUIV(Table!S3;Tableau1[Neuf/Restructure];0);EQUIV(Table!U3;Tableau1[[#En-têtes];[2015]:[2022]];0))

Tableau1[[2015:2022]] c'est mes valeurs de loyers dans le tableau que j'ai créer (feuille 1)

Table!S3 c'est le secteur que je récupère dans mes data (Feuille 2)

Tableau1[Neuf/Restrucutre] c'est la colonne qui correspond aux libellés de secteurs (les libellés de ligne du coup) (Feuille 1)

Table!U3 c'est l'année que je récupère dans mes datas (Feuille 2)

Tableau1[#En-têtes];[2015]:[2022]] c'est les libellés de colonne qui permettent de faire le check avec Table!U3 (Feuille 1)

Si mes libellés de colonnes du tableau en feuille 1 sont les années comme je les ai mise, ça me renvoie #N/A.

Si je remplace par du texte (par exemple "TEST") et que je met mon année dans mes data taggé du texte "TEST", ça fonctionne et ça me renvoie la bonne valeur.

Sauf qu'évidemment dans un soucis de logique, j'aimerai bien que mes libellés de colonnes restent des années, ce qui est une des variables principales de mes données.

Et j'arrive pas à piger pourquoi la formule capte pas quand c'est "2015" mais capte quand c'est "Test". Quelqu'un a une idée ?

J'ai essayé de changer le format de mes cellules en nombre, en texte, etc. Rien n'y fait.

Merci d'avance !

Bonjour à tous !

Si vos valeurs "Années" sont des en-têtes de tableau, elles sont typées texte.

Votre formule INDEX+EQUIV doit donc contenir pour l'année 2023, par exemple, l'élément "2023" et non 2023.

Bonjour JFL, merci pour votre réponse.

Le truc c'est que dans ma formule je renseigne une cellule, pas l'année "à la main" puisque je veux que ça soit dynamique en fonction de l'année qui doit être recherchée dans une autre colonne de mon jeu de données.

EDIT : Visiblement en mettant après le second EQUIV :

EQUIV(TEXTE(Table!U3;"####")

ça fonctionne

Bonjour à tous de nouveau !

Je vous propose d'utiliser la fonction VALEUR.EN.TEXTE :

VALEUR.EN.TEXTE(cellule à traiter)

Merci JFL,

Finalement j'ai fais comme ceci :

=INDEX(Tableau1[[2015]:[2022]];EQUIV(Table!S3;Tableau1[Neuf/Restructure];0);EQUIV(TEXTE(Table!U3;"####");Tableau1[[#En-têtes];[2015]:[2022]];0))

la fonction TEXTE() a suffit a résoudre le soucis ! :)

Bonne journée !

Bonjour à tous de nouveau !

Parfait !

Ne pas omettre de passer le sujet en mode résolu.