Récupérer la valeur de cellulle d'une ensemble de fichers ex
Bonjour,
Je voudrais récupérer les valeurs d'une même cellule de plusieurs fichiers excel se trouvant dans un même dossier mais ayant un nom de fichier différentes.
J'ai donc utilisé la formule suivante :
='C:\Users\Maison fixe\Desktop\AV Concept\FACTURE_2010\[FACTURE640_080110.XLS]Facture'!$M$18
Mais cela signifie que je dois changer à chaque fois le nom du fichier entre crochet.
J'ai voulu faire une formule qui va chercher automatiquement le nom de chaque fichier que j'ai stocké dans une colonne :
=''C:\Users\Maison fixe\Desktop\AV Concept\FACTURE_2010\[" & G12 &"]Facture'!$N$20"
Mais au lieu de mettre mettre le résultat il m'affiche le texte
='C:\Users\Maison fixe\Desktop\AV Concept\FACTURE_2010\[FACTURE640_080110.XLS]Facture'!$N$20.
Savez vous comment faire pour lui faire interpréter la formule et lui faire comprendre qu'il doit donner le résultat et non nous afficher du texte?
Ou avez vous une autre solution?
D'avance merci.
Bonsoir,
Regarde ici on vient de traiter un problème qui ressemble au tien :
https://forum.excel-pratique.com/excel/faire-une-somme-donnee-autre-fichier-t19334.html
J'ai dans ce poste utilisé des noms dynamiques (avec MOIS) mais ça sera plus simple avec toi car tu ne veux récupérer que N20 et pas faire la somme d'une plage
Tu risques d'avoir le même problème, la formule avec INDIRECT ne fonctionne que si le fichier appelé est ouvert.
Si tu installes INDIRECT.EXT à partir de la macro complémentaire MOREFUNC Excel pourra lire dans les fichiers fermés.
A+
Merci, mais j'utilise excel 2010 et ça ne marche pas!
Bonjour,
Tes noms de classeurs ont ils une partie générique (par ex: Factures*)
combien as tu des classeurs a traiter ?
Dans l'attente
Bonjour,
Oui mes classeurs commencent tous par FACTURE puis un nombre (ex:FACTURE647_120210), j'en ai environ 350 à traiter.
Si tu trouves une solution, ça me sauverai la vie car je me vois mal tous les ouvrirent et récupérer la valeur des cellules manuellement.
Merci
Bonjour,
OK, je te propose une macro (sans ouvrir les fichiers factures*)demain dans la matinée...
cellule à récupérer: n20
Bonjour,
Merci de t'être occupé de mon problème mais j'ai trouvé la solution.
Je la poste pour ceux qui recherche aussi:
Sub recup()
Range("A2").Select 'sélectionner la cellule de début
Chemin = "C:\Users\Maison fixe\Desktop\FACTURE_2010\" 'adresse du repertoir
fichier = Dir(Chemin & "*.xls")
Do While fichier <> ""
Workbooks.Open Filename:=Chemin & fichier
Set feuille = ActiveWorkbook.Sheets("Feuil1")
ThisWorkbook.Activate
ActiveCell.Value = feuille.Range("M18").Value
ActiveCell.Offset(0, 1).Value = feuille.Range("M19").Value
ActiveCell.Offset(0, 2).Value = feuille.Range("M20").Value
ActiveCell.Offset(0, 3).Value = feuille.Range("N20").Value
Windows(fichier).Close savechanges:=False
ThisWorkbook.Activate
Range("A65536").End(xlUp).Offset(1, 0).Select
fichier = Dir ' Fichier suivant
Loop
End Sub
Merci de ton aide.
moi je veux bien
peut-être + simple et surtout plus rapide (je n'avais que N20)
Sub recupérer_350cellules()
Dim lig As Long
Dim recap As String, chemin As String, onglet As String
Dim fich As String
Dim start As Single
start = Timer
onglet = "feuil1" ' A ADAPTER
Chemin = "C:\Users\Maison fixe\Desktop\FACTURE_2010\"
Application.ScreenUpdating = False
Range("A2:B400").ClearContents
lig = 2
ChDir chemin
fich = Dir("facture*.xls")
While fich <> ""
'source: instruction dite de "Walkenbach"
Cells(lig, 1) = Left(fich, Len(fich) - 4)
Cells(lig, 2) = ExecuteExcel4Macro("'" & chemin & "\[" & fich & "]" & onglet & "'!R20C14") 'R20C14<==> N201
lig = lig + 1
fich = Dir
Wend
MsgBox "récupération terminée avec succès en " & Timer - start & " secondes."
End Sub