Regrouper les données d'une colonne B sur chaque donnée unique d'une colonn

Bonjour,

Je recherche à regrouper les données d'une colonne B sur chaque donnée unique d'une colonne A

Voici mes données :

Colonne A Colonne B

A 1

B 1

C 1

D 2

E 4

A 3

B 5

C 2

Voici le résultat souhaité.

Colonne A Colonne B

A 1,3

B 1,5

C 1,2

D 2

E 4

Avez-vous une solution ?

Un tout grand merci.

Benoit

Bonjour,

une solution par macro:

Sub macro()
 Dim T, TT, i As Long, Dico

 Set Dico = CreateObject("Scripting.Dictionary")
 With Worksheets("Feuil2") '<= nom de la feuille à adapter
 T = .Range("A1:B" & .Range("A" & Rows.Count).End(xlUp).Row)
 For i = LBound(T, 1) To UBound(T, 1)
    If Not Dico.Exists(T(i, 1)) Then
        Dico(T(i, 1)) = T(i, 2)
    Else
        Dico(T(i, 1)) = Dico(T(i, 1)) & "," & T(i, 2)
    End If
 Next
 TT = Application.Transpose(Array(Dico.keys, Dico.Items))

 .Range("C1").Resize(UBound(TT, 1), 2) = TT  ' <== emplacement à adapter
 End With
End Sub

le résultat est copié en colonnes Cet D

A+

Merci.