Masqué les numeros de ligne et colonne

Bonjour

je cherche a masquer les numeros de ligne et de colonne lorsque je mets mon classeur Excel en fullscreen via un code VBA

pour le plein ecran, pas de soucis,

Private Sub Workbook_Activate()
'Mise en mode plein écran
Application.DisplayFullScreen = False
End Sub

mais pour les entetes je sais que ça se fait en direct via mise en page / option de feuille de calcul / entête / afficher

merci de votre aide

bonjour,

Sub test()
Application.ScreenUpdating = False
For i = 1 To Worksheets.Count
Worksheets(i).Activate
ActiveWindow.DisplayHeadings = False
Next
Worksheets(1).Activate
End Sub

A+

Impeccable!!!

après quelques modif, ça me donne cela:

Private Sub Workbook_Activate()
Dim i As Byte

With Application
    .DisplayFullScreen = True           'Mise en mode plein écran
    .DisplayFormulaBar = False          'affichage de la barre de formule
    .ScreenUpdating = False             'rafraichissement du programme
End With

For i = 1 To Worksheets.Count           ' sur chaque onglet
Worksheets(i).Activate
ActiveWindow.DisplayHeadings = False    'affichage des entetes (num colonne et ligne)
ActiveWindow.DisplayGridlines = False   'affichage du quadrillage
Next

Feuil1.Activate

End Sub

merci Galopin

Attention ce genre de macro est souvent détesté en particulier sur les Forums car elle fout le bordel dans la config des GR (GentilsRépondeurs)

En effet modifier les paramètres d'environnement d'Excel revient à modifier les paramètres de travail habituels de ces derniers (en particuliers tous ceux de niveau Application, WindowState etc...)

Aussi il est recommandé de mémoriser la config Utilisateur avant de prendre la main sur ces paramètres et de les restituer avant de quitter. A défaut tu risques fort de te faire insulter par les GR si tu ne respectes pas leur environnement de travail...

Ceci oblige à une config bien particulière du Workbook, qui Mémorise la config de l'utilisateur à l'entrée , en définie une nouvelle, et la restore en sortie.

De plus il faut prévoir éventuellement une config restorée parfois partiellement en cas de désactivation de la fenètre ou du classeur et une réactivation au retour...

L'exemple suivant montre une batterie de macro de mémorisation, Définition d'une config, restauration. (et encore dans mon modèle il n'est pas question de WindowsState...)

Private Sub Workbook_Activate()
Application.ScreenUpdating = False
   MemEnv
   DefEnv
   Worksheets("Accueil").Activate
End Sub

Private Sub Workbook_Deactivate()
   ResEnv
End Sub

Private Sub DefEnv()
   Dim S
   ActiveWindow.DisplayWorkbookTabs = False
   Application.DisplayFormulaBar = False
   Application.DisplayScrollBars = False
   For Each S In ThisWorkbook.Sheets
     S.Activate
     ActiveWindow.DisplayHeadings = False
   Next S
End Sub
Private Sub MemEnv()
   Dim S
   YDO = ActiveWindow.DisplayWorkbookTabs
   YDS = Application.DisplayScrollBars
   YDF = Application.DisplayFormulaBar
   For Each S In ThisWorkbook.Sheets
     S.Activate
     ActiveWindow.DisplayHeadings = YDH
   Next S
End Sub

Private Sub ResEnv()
   Dim S
   Application.ScreenUpdating = False
   ActiveWindow.DisplayWorkbookTabs = YDO
   Application.DisplayScrollBars = YDS
   Application.DisplayFormulaBar = YDF
   For Each S In ThisWorkbook.Sheets
     S.Activate
     ActiveWindow.DisplayHeadings = YDH
   Next S
End Sub

Les variables YDO, YDS, YDF, YDH sont définie dans Module1...

Public YDO, YDS, YDF, YDH

A+