Ecrire une date statique sur Excel

Bonjour à tous,

J'aimerais ecrire automatiquement une date statique sur excel (automatiser le Ctrl+;) mais je ne sais pas comment m'y prendre.

Je m'explique: j'ai une selection de cases (A2 à A60) qui sont vides au début de chaque mois, chaque jour, je mets à jour cette liste là en rajoutant deux ou trois nombres. Ma question est: est ce qu'il existe un moyen d'ecrire à côte de chaque case remplie la date à laquelle celle-ci a été remplie? Quelque chose du genre: Dès que la case A5 est non vide, alors faire "Ctrl+;" cela me permet à la fin du mois de savoir quelle valeur j'ai rentré chaque jour, sans devoir taper manuellement la date à cote de chaque nombre.

Merci pour votre aide !

Salut le fil

Dans l'évènement Change de la feuille tu colles ce code.

Private Sub Worksheet_Change(ByVal Target As Range)
    With Target
        If Not Intersect(Range("A2:A60"), Target) Is Nothing Then
            If .Value <> vbNullString Then
                With .Offset(0, 1)
                    .Value = Date
                    .EntireColumn.AutoFit
                End With
            Else
                .Offset(0, 1).Value = vbNullString
            End If
        End If
    End With
End Sub

Bonjour,
Une autre proposition !?
Cdlt.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("A2:A60")) Is Nothing And Target.CountLarge = 1 Then
        Target.Offset(, 1).Value = IIf(IsEmpty(Target), vbNullString, VBA.Date)
    End If
End Sub

Bonjour à tous,

Merci pour vos réponses, il suffit simplement de copier ce programme dans le VBA ? car lorsque j'enregistre les modifications sur VBA et que j'inscrit un nombre dans la case A5 par exemple, aucune date ne s'inscrit dans la case B5.... Peut être une fausse manip de ma part (je maitrise encore mal le VBA....)

Merci beaucoup pour votre aide et votre temps

Salut le fil

Dans l'environnement VBE tu sélectionnes la feuille avec un double clic, puis tu sélectionnes Worksheet et l'évènement Change. Ensuite tu colles le code. (Attention de ne pas remettre la première et dernière ligne. sinon plantage.

Merci beaucoup pour votre aide ! Cela fonctionne.

Bonne journée !