Cout total d'un projet en fonction du prix, des accords, du volume et année

Bonjour à tous,

Je cherche à mettre à jour un fichier excel qui me donnera le prix total sur l'ensemble du projet en fonction du prix, des accords de prix et du volume.

J'ai essayé plusieurs formules SI, SI.CONDITIONS, SI.MULTIPLE, etc sans succès ) .

J'aimerai que la formule puisse suivre le chemin ci-dessous :

- Détecter la première année avec du volume soit "Volume 2024" (I3) et la multiplier par le "Prix" (C3)

- Détecter la seconde année avec du volume soit "Volume 2025" (J3) et la multiplier par le "Prix SOP+1" (D3)

- Détecter la troisième année avec du volume soit "Volume 2026" (K3) et la multiplier par le "Prix SOP+2" (E3)

- Détecter la quatrième année avec du volume soit "Volume 2027" (L3) et la multiplier par le "Prix SOP+3" (F3)

- Détecter les années années restantes soit "Volume 2028" (M3) et "Volume 2029" (N3) et les multiplier par le "Prix SOP+3" (F3)

- Additionner l'ensemble de ces calculs dans la cellule "Total" (O3) afin d'obtenir le cout total du projet.

Ci-joint la draft de l'excel si-besoin,

Aussi, l'idée de ce fichier est de pouvoir intégrer par la suite d'autres lignes qui pourraient avoir un volume commençant en 2022 ou 2023 par exemple.

Donc le fichier doit détecter les premiers volumes et s'adapter en fonction des différents prix par année.

Je vous remercie d'avance pour votre aide,

N'hésitez pas si vous avez des questions ou besoin de plus d'informations,

Merci

Bonjour

=SOMMEPROD(DECALER(G3;;MIN(SI(G3:N3>0;COLONNE(G3:N3)-6;9^9))-1;;MIN(NB.SI(G3:N3;">0");4));DECALER(C3;;;;MIN(NB.SI(G3:N3;">0");4)))+SIERREUR(SOMMEPROD(DECALER(G3;;NB.SI(G3:N3;">0")-MIN(NB.SI(G3:N3;">0");4)+2;;NB.SI(G3:N3;">0")-MIN(NB.SI(G3:N3;">0");4))*F3);0)

Bonjour Chris,

Merci beaucoup pour ton aide !

Je ne connaissais pas la formule DECALER et je pense que ca va bien m'aider pour trouver la réponse

Peut être que j'ai mal exprimé le problème, mais quand je rentre ta formule, le résultat attendu n'est pas le bon.

Tu peux trouver ci-dessous le résultat attendu :

Ci-dessous le excel :

En tout cas, je vais continuer à bosser dessus.

N'hésite pas si tu as des conseils,

Bonjour

Que saisit-on en colonne 2028 et 2029 si cela s'arrête en 2027 ?

Bonjour

Il y a peut-être plus court mais ceci semble OK

SOMMEPROD(DECALER(G3;;MIN(SI(G3:N3>0;COLONNE(G3:N3)-6;9^9))-1;;MIN(NB.SI(G3:N3;">0");4));DECALER(C3;;;;MIN(NB.SI(G3:N3;">0");4)))+SIERREUR(SOMMEPROD(DECALER(G3;;MIN(SI(G3:N3<>0;COLONNE(G3:N3)-6;9^9))+MIN(NB.SI(G3:N3;">0");4)-1;;MAX(SI(G3:N3<>0;COLONNE(G3:N3)-6;0))-MIN(SI(G3:N3<>0;COLONNE(G3:N3)-6;9^9))-MIN(NB.SI(G3:N3;">0");4)+1)*F3);0)

Le premier SOMMEPROD n'a pas changé mais le second pour trouver ce qui existe entre des 0 avant et des 0 après

Bonjour à tous !

Pour le "fun" mais avec 365 Insider, formule en O3 :

=LET(
v_;TRANSPOSE(FILTRE(G3:N3;G3:N3>0));
p_;TRANSPOSE(C3:F3);
g_;PRENDRE(ASSEMB.V(p_;SEQUENCE(10;;MIN(p_);0));NBVAL(v_));
ARRONDI(SOMMEPROD( v_ * g_ );2)
)