Validation des données

Question

Bonjour, je cherche à créer une liste déroulante sur un tableau, dont les données viennent s'incrémenter, sans doublons et sans vides. 3 jours que je me casse la tête. Merci d'avance. Xavier...

ThauThème · Answer

Bonjour Xave, bonjour le forum,

Désolé mais je me sais pas faire ça par formule mais je crois l'avoir déjà vu...

Je te propose une solution VBA ou je considère la plage de données dans la colonne A et la liste de validation de données en B1 (voir fichier exemple). Le code :

Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim I As Integer 'déclare la variable I (Incrément)
Dim L As String 'déclare la variable L (Liste)

Set O = Worksheets("Feuil1") 'définit l'ontglet O (à adapter à ton cas)
DL = O.Cells(Application.Rows.Count, "A").End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne A (à adapter à ton cas) de l'onglet O
TV = Range("A1:A" & DL) 'définit le tableau des valeurs TV (colonne à adapter à ton cas)
Set D = CreateObject("scripting.Dictionary") 'définit le dictionnaire D
For I = 1 To DL 'boucle sur toutes les lignes I du tableau des valeurs TV
    If TV(I, 1) <> "" Then D(TV(I, 1)) = "" 'si la donnée ligne I colonne 1 de TV n'est pas vide alimente le dictionnaire D avec cette donnée
Next I 'prochaine ligne de la boucle
L = Join(D.keys, ",") 'définit la liste L (union des élément du dictionnaire D sans doublon (les clés) séparés par une virgule)
With Range("B1").Validation 'prend en compte la validation de données de la cellule B1
    .Delete 'supprime une éventuelle validation existante
    .Add xlValidateList, Formula1:=L 'définit la liste L comme liste de validation de données
End With 'fin de la prise en compte de la validation de données de la cellule B1
End Sub

Le fichier :

8xave-ep-v01.xlsm (16.54 Ko)