Ouverture et sauvegarde de ficher Word sous un autre nom

bonjour tout le monde,
j'arrive à ouvrir un document word mais je n'arrive pas à l'enregistrer sous un autre nom
Code

<table><tbody><tr><td valign="top"><pre>Private Sub CommandButton1_Click()

Dim FichierWord As String
Dim NouvNomFichier As String
FichierWord = ThisWorkbook.Path & "\BASE COURANTE\CONVENTIONS ECHELONNEMENTS\CONVENTION ECHELONNEMENT PERSONNE MORALE.docx"
NouvNomFichier = ThisWorkbook.Path & "\BASE COURANTE\CONVENTIONS ECHELONNEMENTS\" & "TEST" & ".docx"

Set WordApplication = CreateObject("Word.Application")

If Dir(FichierWord) <> "" Then

   WordApplication.Visible = True
   WordApplication.Documents.Open FichierWord

   ActiveDocument.SaveAs NouvNomFichier

Else

   MsgBox "Fichier Introuvable"
   Exit Sub

End If

End Sub</pre></td></tr></tbody></table>

est ce que quelqu’un peut me dire ou est l'erreur

Bonjour,

Référence Word à cocher. A adapter.

Option Explicit

Sub TestSauvegardeFichierWord()

Dim FichierWord As String, NouvNomFichier As String

    FichierWord = ThisWorkbook.Path & "\BASE COURANTE\CONVENTIONS ECHELONNEMENTS\CONVENTION ECHELONNEMENT PERSONNE MORALE.docx"
    NouvNomFichier = ThisWorkbook.Path & "\BASE COURANTE\CONVENTIONS ECHELONNEMENTS\" & "TEST" & ".docx"

    SauvegardeFichierWord FichierWord, NouvNomFichier

End Sub

Sub SauvegardeFichierWord(ByVal FichierWord2 As String, ByVal NouvNomFichier2 As String)

Dim WordApp As Word.Application
Dim WordDoc As Word.Document

    Set WordApp = CreateObject("Word.Application")
    With WordApp
         .Visible = True
         Set WordDoc = .Documents.Open(FichierWord2)
    End With

    With WordDoc

         .SaveAs2 Filename:=NouvNomFichier2, FileFormat:=12
         ' Suite du code
         ' .....

     End With

      WordDoc.Close True
      WordApp.Quit

      Set WordApp = Nothing:  Set WordDoc = Nothing

End Sub

Une façon plus universelle de copier et déplacer :

Option Explicit

Sub TestCopierUnFichier()

Dim CheminSource As String, CheminCible As String

    CheminSource = "XXXXX" & "\" & "FichierACopier.Ext"
    CheminCible = "YYYYY" & "\" & "NouveauNomFichier.Ext"
    CopierUnFichier CheminSource, CheminCible

End Sub

Sub CopierUnFichier(ByVal CheminSource2 As String, ByVal CheminCible2 As String)

Dim oFSO As Object

    Set oFSO = CreateObject("Scripting.FileSystemObject")
    If oFSO.FileExists(CheminSource2) Then oFSO.CopyFile CheminSource2, CheminCible2

    Set oFSO = Nothing

End Sub

Bonjour merci pour la réponse avec la première proposition j'ai un message d’erreur

avec me remerciements

Dans ma réponse, j'ai indiqué Référence Word à cocher. Sinon typer les variables en Object.

Problème réglé ?

Bonjour le fil

@Eric Kergresse, aucun besoin de cocher quelque référence que ce soit si on fait du Late binding

Ce que l'on fait avec

Set WordApp = CreateObject("Word.Application")

Voici le code testé et fonctionnel

Sub TestSauvegardeFichierWord()
  Dim FichierWord As String, NouvNomFichier As String
  '
  FichierWord = "C:\Temp\FichierWord1.docx"
  NouvNomFichier = "C:\Temp\NewFichierWord.docx"
  '
  SauvegardeFichierWord FichierWord, NouvNomFichier
End Sub

Sub SauvegardeFichierWord(ByVal FichierWord2 As String, ByVal NouvNomFichier2 As String)
  Dim WordApp As Object, WordDoc As Object

  Set WordApp = CreateObject("Word.Application")
  With WordApp
    .Visible = True
    Set WordDoc = .Documents.Open(FichierWord2)
  End With
  With WordDoc
    .SaveAs2 Filename:=NouvNomFichier2, FileFormat:=12
    ' Suite du code
    ' .....
  End With
  WordDoc.Close True
  WordApp.Quit
  Set WordApp = Nothing:  Set WordDoc = Nothing
End Sub

Pour celles et ceux qui passeront, attention, il faut que le chemin et le nom de fichier soit bon

A+

Salut Bruno,

En phase développement c'est toujours mieux de référencer Word pour bénéficier de "l'intellisense". On passe en late binding lorsque tout est OK, en tout cas, c'est ma méthode.

Sinon, même message sur un autre forum Excel.

Salut Eric,

Je pratique de la même manière, mais là tout est OK

Effectivement, je clôture ce sujet et j'aurais Mister THCH à l'oeil

Petit rappel si Mister repasse par ici

• Ne postez pas la même question sur un autre forum pour éviter de faire perdre bêtement du temps aux membres sur un problème qui peut être déjà résolu sur l'autre forum. L'inverse est également valable, si vous avez déjà posé votre question sur un autre forum, ne créez pas un doublon sur ce forum (à moins d'avoir clôturé le sujet sur l'autre forum).

Bravo pour le respect des autres

A+