[VBA] - Reset des feuilles sauf une colonne

Bonjour à tous,

je souhaiterais créer une macro qui permet de réinitialiser toutes mes BDD sauf pour une colonne, comment faire ? Je pense que ci-dessous c'est la bonne macro mais je ne sais pas créer une exception pour les colonnes mentionnées...

Sub RESET()
Sheets("Feuille1").Range("A4:N554").ClearContents (sauf pour la colonne J)
Sheets("Feuille2").Range("A4:N554").ClearContents (sauf pour la colonne J)
Sheets("Feuille3").Range("A4:O554").ClearContents (sauf pour la colonne J)
Sheets("Feuille4").Range("A4:O554").ClearContents (sauf pour la colonne J)
Sheets("Feuille5").Range("A4:O554").ClearContents (sauf pour la colonne J)
Sheets("Feuille6").Range("A4:T554").ClearContents (sauf pour la colonne O)
End Sub

Merci de votre aide !

Bonjour,

A tester :

Sub Test()

    EffacerLesColonnes Sheets("Feuil1"), "N", "J"
    EffacerLesColonnes Sheets("Feuil2"), "N", "J"
    EffacerLesColonnes Sheets("Feuil3"), "O", "J"
    EffacerLesColonnes Sheets("Feuil4"), "O", "J"
    EffacerLesColonnes Sheets("Feuil5"), "O", "J"
    EffacerLesColonnes Sheets("Feuil6"), "T", "O"

End Sub

Sub EffacerLesColonnes(ByVal Sh As Worksheet, ByVal DerniereColonne As String, ByVal ColonneAEcarter As String)

Dim I As Integer, ColonneFin As Integer

  With Sh
       ColonneFin = .Cells(1, DerniereColonne).Column
       For I = ColonneFin To 1 Step -1
           Select Case .Cells(1, I).Column
                  Case .Cells(1, ColonneAEcarter).Column

                  Case Else
                       .Range(.Cells(4, I), .Cells(554, I)).ClearContents
           End Select
       Next I
  End With

End Sub

Bonjour,
Une variante.
Cdlt.

Public Sub CleanData()
Dim ws As Worksheet, rng As Range
    For Each ws In ActiveWorkbook.Worksheets
        Select Case ws.Name
            Case "Feuil1", "Feuil2", "Feuil3", "Feuil4", "Feuil5":
                Set rng = Union(ws.Range("A4:I554"), ws.Range("K4:N554"))
            Case "Feuil6":
                Set rng = Union(ws.Range("A4:N554"), ws.Range("P4:T554"))
        End Select
        rng.ClearContents
    Next ws
End Sub

Merci de votre aide !