Comparer deux colonnes avec Excel

Bonjour à tous !

J'ai vu qu'il y avait déjà des messages similaires mais malgré plusieurs tests et beaucoup de temps passé dessus je n'arrive pas à comparer deux colonnes avec excel. C'est pour cela que je me permets avec ma toute petite expérience d'excel de venir vous poser ma question ici.

Je souhaiterais comparer deux colonnes Excel (une colonne A feuille 1 et une colonne A feuille 2 pour voir si l'une des références fournies colonne A feuille 1 ne correspond pas à l'une des références colonne A feuille 2)

J'ai essayé avec la fonction SI en mettant les deux colonnes cote à cote en colonne N et M mais cela ne compare qu'une seule case...=SI(M2=N2;"Correspondance";"Aucune correspondance").

Bref j'ai essayé de reprendre une autre formule donnée par le forum mais pareil ça n'a pas l'air de fonctionner : =SIERREUR(INDEX(feuil5!C:C;EQUIV(B3;feuil6!B:B;0));""). Est ce que cela pourrait juste m'indiquer si l'une des références de la colonne est identique avec une autre ?

A l'aide et merci d'avance à ceux qui voudraient bien essayer de m'aider !!

Bonjour,

Dans Feuille1, vous ajoutez une colonne et vous appliquez la formule :

=SIERREUR(RECHERCHEV(A2;Feuille2!$A$1:$A$308;1;FAUX);"")

Bonjour le fil, bonjour le forum,

Une proposition VBA (au cas où...) :

Sub Macro1()
Dim O1 As Worksheet 'déclare la variale O1 (Onglet 1)
Dim O2 As Worksheet 'déclare la variale O1 (Onglet 2)
Dim TV As Variant 'déclare la variable TV (tableau des Valeurs )
Dim I As Integer 'déclare la variable I (Incrément)
Dim J As Integer 'déclare la variable J (incrément)

Set O1 = Worksheets("Feuille1") 'définit l'onglet O1
Set O2 = Worksheets("Feuille2") 'définit l'onglet O2
O1.Columns(1).Interior.ColorIndex = xlNone 'supprime les couleurs de la colonne 1 de l'onglet O1
O2.Columns(1).Interior.ColorIndex = xlNone 'supprime les couleurs de la colonne 1 de l'onglet O2
TV = O1.Range("A1").CurrentRegion 'définit la tableau des valeurs TV (onglet O1)
For I = 2 To UBound(TV, 1) 'boucle sur toutes les lignes I du tableau des valeur TV (en partant de la seconde)
    's'il n'existe aucunne occurrence de TV(I,1) dans la colonne 1 de l'onglet O2, colore la cellule ligne I colonne 1 de O1 en vert
    If O2.Columns(1).Find(TV(I, 1), , xlValues, xlWhole) Is Nothing Then O1.Cells(I, 1).Interior.ColorIndex = 4
Next I 'prochaine ligne de la boucle
O1.Activate 'active l'onglet O1
MsgBox "Données comparées. En vert toutes les cellules de Feuille1 n'apparaissent pas dans Feuille2." 'message
TV = O2.Range("A1").CurrentRegion 'définit la tableau des valeurs TV  (onglet O2)
For I = 2 To UBound(TV, 1) 'boucle sur toutes les lignes I du tableau des valeur TV (en partant de la seconde)
    's'il n'existe aucunne occurrence de TV(I,1) dans la colonne 1 de l'onglet O1, colore la cellule ligne I colonne 1 de O2 en violet
    If O1.Columns(1).Find(TV(I, 1), , xlValues, xlWhole) Is Nothing Then O2.Cells(I, 1).Interior.ColorIndex = 7
Next I 'prochaine ligne de la boucle
O2.Activate 'active l'onglet O2
MsgBox "Données comparées. En violet, toutes les cellules de Feuille2 n'apparaissent pas dans Feuille1." 'message
End Sub