Colonne protégée + filtres

Bonjour,

J'ai créé un tableau avec en en-tête des filtres.

Dans la Colonne B, j'ai une formule que je veux protéger et être le seul à avoir accès afin que les autres utilisateurs ne puissent pas effacer cette formule.

J'ai donc protégé la Colonne B mais du coup, les utilisateurs avec qui je partage le fichier sont bloqués à cause des filtres.

Est-il possible de protéger une Colonne tout en conservant l'utilisation des filtres pour l'ensemble des utilisateurs ?

Merci pour vos réponses.

Bonjour,

la formule est-elle sur chaque cellule de la colonne, ou juste sur la ligne 1 (formule de type arrayformula) ?

Bonjour Steelson,

Je viens de découvrir dans un autre post les formules de type Arrayformula mais je n'arrive pas encore à les mettre en place.

Pour le moment la formule est dans chaque cellule.

Exemple : B4 / B5 / B6 ......

quelle est cette formule mystérieuse ?

si par exemple simplifié cette formule est dans B2 comme suit =A2*2

alors en B1 tu peux écrire

={"titre de la colonne";arrayformula(if(A2:A="";;A2:A*2))}

note que {} permet d'écrire plusieurs fonctions qui seront ici empilées grâce à ; (bon, le première est simple, il s'agit du titre)

Pas de formule mystérieuse

https://docs.google.com/spreadsheets/d/1MvKT_9uMUmup6BLsVQc3GsBocMC8Ac-RY7H8cQAuD4Q/edit?usp=sharing

En colonne D, je souhaite protéger ces formules qui sont répétées dans chaque cellule de D4 à D11 dans l'exemple.

Je souhaite malgré tout que les autres utilisateurs puissent utiliser les filtres de A4 à U4 ce qui bloque apparemment si je protège la colonne D.

Cerise sur le gâteau, j'aimerais comprendre l'utilité de la formule arrayformula ...

Essaie avec ceci en D3 en supprimant tout ce qu'il y a en dessous de D3

={"LIBELLE L-COMMERCE";"";arrayformula(IF(C5:C="";"";IFERROR(VLOOKUP(C5:C;importrange("12bytUuCJMEqyY7-YRD52VwzO3K2klC-onJMuVH4jA98";"$C:$D");2;0);"EAN INCONNU DANS REFLEX")))}

je ne peux pas intervenir sur la feuille car ... les cellules sont protégées

ensuite tu ne protège que D3 et non la colonne

Bonjour Steelson,

J'étais très réfractaire à Sheet mais j'avance à grand pas grâce à ton aide.

Au top cette fonction arrayformula. J'ai fait comme tu m'as expliqué et tout fonctionne. Je peux enfin trier tout en protégeant la cellule

Merci et à la prochaine pour une nouvelle question

Nouch a écrit :

J'étais très réfractaire à Sheet mais j'avance à grand pas grâce à ton aide.

J'étais un peu hésitant au début, j'ai maintenant beaucoup de difficultés à retourner vers excel.

Mais beaucoup restent encore réfractaires et certains y viennent obligés parce que leur entreprise a changé de tableur.

Au début, je passais 10x plus de temps sur un sujet que sur le même sur excel, et maintenant je trouve beaucoup de facilité et de rapidité dans un jeu de légo car on ré-assemble facilement ce qui a déjà été fait.

Le plus fun : les formules ...

J'ai déjà une question

Comment ré-autoriser lorsque je recopie une formule avec un lien importrange ?

je ne suis pas sûr de bien comprendre, je n'ai pas beaucoup l'expérience des protections

mais au passage, sur un autre sujet, j'aurais tendance à ne fait qu'un seul importrange dans un onglet dédié à cela et "brancher" mes formules sur cet onglet

bon, cela ne répond pas à la question pour autant

Je vais continuer à chercher ...

Du coup grâce à la fonction arrayformula, j'adapte mes tableaux mais j'ai un petit soucis.

J'avais ces formules en colonne O4 à O... :

=SIERREUR(SI(OU(G4="";A4<>"";L4="";L4="AVOIR");"";RECHERCHEV(G4;importrange("1BqWOHlxNxtKy7j4qbBosEI0kxSKraGpZpul2LTQ7s9A";"$B:$D");3;0));"PAF")

J'ai voulu les remplacer en O2 par :

="PAF";"";arrayformula(SIERREUR(SI(OU(G4:G="";A4:A<>"";L4:L="";L4:L="AVOIR");"";RECHERCHEV(G4:G;importrange("1BqWOHlxNxtKy7j4qbBosEI0kxSKraGpZpul2LTQ7s9A";"$B:$D");3;0));"PAF"))}

mais je n'obtiens aucun résultat. Je ne vois pas vraiment ou est le problème ...

Le problème est que arrayformula n'accepte pas les OU ou les ET, il faut les remplacer par respectivement les opérateurs + et *

Il faut transformer les conditions du type OU(condiiton1;condition2) en (condition1+condition2)>0

et ET(condiiton1;condition2) en (condition1*condition2)>0

cela devrait faire alors

="PAF";"";arrayformula(SIERREUR(
SI((G4:G="")*(A4:A<>"")*(L4:L="")*(L4:L="AVOIR")>0;
"";RECHERCHEV(G4:G;importrange("1BqWOHlxNxtKy7j4qbBosEI0kxSKraGpZpul2LTQ7s9A";"$B:$D");3;0));"PAF"))}

j'espère qu'il ne manque pas de parenthèses

Top

J'ai remplacé (G4:G="")*(A4:A<>"")*(L4:L="")*(L4:L="AVOIR") par (G4:G="")+(A4:A<>"")+(L4:L="")+(L4:L="AVOIR") car c'est la condition OU

J'ai encore un soucis avec la fonction concatener + arrayformula

J'ai voulu remplacer cette fonction

=SI(F5="";CONCATENER(C5;V5);CONCATENER(C5;F5))

par

={"EAN + MILLESIME RECU";"";arrayformula(SI(F5:F="";CONCATENER(C5:C&V5:V);CONCATENER(C5:C&F5:F)))}

mais le résultat n'est pas concluant

={"EAN + MILLESIME RECU";"";arrayformula(SI(F5:F="";(C5:C&V5:V);(C5:C&F5:F)))}

CONCATENER ne sert à rien en fait !