Réunir deux feuilles d'un même document dans une troisième

Bonjour,

Dans un document, j'ai deux feuilles (Résultat et Résultat_suite) créées à partir de deux formulaires différents.

Les colonnes dans chacune de ces feuilles ne sont pas les mêmes sauf la colonne A qui contient une clé identique pour les deux formulaires

Pour compléter un questionnaire du formulaire Résultat_suite il faut déjà qu'il en existe un dans le formulaire Résultat.

Le formulaire Résultat_suite peut être rempli dans le désordre.

Par contre, il n'y a pas obligatoirement besoin de données pour le formulaire Résultat_suite pour toutes les données du formulaire Résultat.

Je voudrai dans une troisième feuille regrouper toutes mes colonnes de de mes deux premières feuilles.

Petit exemple pour être plus claire

Feuille Résultat

Feuille Résultat_suite

Feuille Résultat_global

Par contre je n'ai pas seulement 6 lignes et 7 colonnes mais des dizaines voire des centaines de lignes et une cinquantaine de colonnes.

Il n'est pas possible de regrouper les formulaires car ils ne sont pas remplis par la même personne.

Pensez vous que cela soit possible ?

Merci

Coloc

Bonjour,

en A1

={'Résultat'!A:E\arrayformula(iferror(vlookup('Résultat'!A:A;'Résultat_suite'!A:C;{2\3};0)))}

Bonjour Steelson,

Merci déjà de m'avoir répondu.

La formule fonctionne, c'est génial. J'ai juste un problème avec le rapatriement du deuxième tableau.

Il n'est pas dû à la formule mais à ma compréhension.

Je n'arrive pas à trouver ce que je dois mettre à la place du {2\3} sachant que j'ai en tout 25 colonnes.

Coloc

voici ma formule :

={'Réponses'!A:BI\arrayformula(SIERREUR(RECHERCHEV('Réponses'!A:A;'Réponses_suite'!A:Y;{2/25};0)))}

Me revoilà,

J'ai compris mon erreur, je mettais un slash à la place d'un anti slash

ça fonctionne

Voici la formule correcte qui marche pour moi. Après, je ne sais pas s'il y a une possibilité pour mettre directement de la colonne 2 à la 25

Coloc a écrit :

Je n'arrive pas à trouver ce que je dois mettre à la place du {2\3} sachant que j'ai en tout 25 colonnes.

il faudrait alors mettre ceci

{2\3\4\5\6\7\8\9\10\11\12\13\14\15\16\17\18\19\20\21\22\23\24\25}

qui heureusement peut se construire avec sequence

="{"&JOIN("\";sequence(1;columns('Résultat_suite'!A:Y);2;1))&"}"

d'où la formule

={'Résultat'!A:E\arrayformula(iferror(vlookup('Résultat'!A:A;'Résultat_suite'!A:Y;{2\3\4\5\6\7\8\9\10\11\12\13\14\15\16\17\18\19\20\21\22\23\24\25};0)))}

par contre, je ne peux pas mixer ici les formules (ce qui serait possible avec query)

A noter

\ veut dire que je juxtapose des colonnes

; veut dire que je superpose

je vais réfléchir comment mettre de 2 à 25 ... c'est pas (encore) gagné !

Si il n'y a pas d'espace dans tes données, on peut les rassembler dans une seule colonne et ensuite les re-splitter

Pour tout rassembler dans une colonne

=transpose(query(transpose('Résultat_suite'!A:Y);;COLUMNS('Résultat_suite'!A:Y)))     

d'où :

={'Résultat'!A:E\arrayformula(iferror(split(vlookup('Résultat'!A:A;{'Résultat_suite'!A:A\transpose(query(transpose('Résultat_suite'!A:Y);;COLUMNS('Résultat_suite'!A:Y)))};{2\3};0);" ")))}

S'il y a des espaces, il faut alors d'abord les remplacer par un espace insécable

=transpose(query(transpose(ARRAYFORMULA(SUBSTITUTE('Résultat_suite'!A:Y;" ";char(160))));;COLUMNS('Résultat_suite'!A:Y)))

et enfin

={'Résultat'!A:E\arrayformula(iferror(split(vlookup('Résultat'!A:A;
{'Résultat_suite'!A:A\transpose(query(transpose(ARRAYFORMULA(SUBSTITUTE('Résultat_suite'!A:Y;" ";char(160))));;COLUMNS('Résultat_suite'!A:Y)))};
{2\3};0);" ")))}

en espérant qu'il n'y ait pas d'espace en colonne A également !

Bonjour Steelson,

Je t'avouerai que finalement je n'ai pas utilisé ta deuxième partie afin de réunir toutes les colonnes car en regardant vraiment mon besoin, il se trouve que je ne prends pas toutes les colonnes mais certaines.

Par contre ta première formule fonctionne très bien pour moi.

Encore merci pour ton aide

Coloc