Dupliquer champs si cellule vide + boucler en VBA

Bonjour à tous,

J'ai cherché sur le forum mais je ne trouve pas la solution a mon problème, pourtant simple...

Ci-joint le fichier que j'essaie d'obtenir via VBA :

Les cellules recherchés sont en jaune.

Merci par avance !

Balek

Bonjour,

Option Explicit

Sub RemplirLesCellulesVides()

Dim I As Integer, J As Integer, DerniereLigne As Integer, DerniereColonne As Integer
Dim LaTable As ListObject
Dim AireCdes As Range
Dim TableNom As String
Dim Sh As Worksheet

    Sheets("Import").Copy after:=Sheets(Sheets.Count)
    Set Sh = ActiveSheet

    With Sh

         DerniereLigne = .Cells(.Rows.Count, 2).End(xlUp).Row
         DerniereColonne = .Cells(1, .Columns.Count).End(xlToLeft).Column
         TableNom = "Table" & Format(Sheets.Count, "00")
         Set LaTable = .ListObjects.Add(xlSrcRange, Range(.Cells(1, 1), .Cells(DerniereLigne, DerniereColonne)), , xlYes)

         With LaTable
              .Name = TableNom
             Set AireCdes = .ListColumns("num_cde").DataBodyRange
             For I = 1 To AireCdes.Count
                 For J = 0 To DerniereColonne - 1
                     With AireCdes(I).Offset(0, J)
                          If .Value = "" Then
                             .Value = AireCdes(I - 1).Offset(0, J)
                             .Interior.Color = RGB(255, 255, 0)
                        End If
                     End With
                Next J
             Next I
         End With
    End With

    Set Sh = Nothing: Set LaTable = Nothing: Set AireCdes = Nothing

End Sub

Bonjour,

C'est top, merci beaucoup !!

Balek