Ventilé des information en vrac dans une autres feuilles en colonne

bonjour à tous,

dans un premier temps merci de votre aide et du temps que vous voudrez bien passer à m'aider.

je suis débutant en macro mais j'essaie de m'améliorer.

j'ai une feuille de saisie ("FICHE") ou je rentre des informations

je souhaite en appuyant sur un bouton récupérer ces donnés pour les mettre dans la feuille "RECAP" en colonne. une fois fini la feuille "FICHE" redevient vierge.

tous cela j'arrive ma difficulté réside sur le fait que je voudrait que les fiches de "RECAP" se mette les une après les autres. et sa je n'y arrive pas. donc si vous pouvez suis preneur.

voici ma macro:

Sub ventillation()

'selection des donnée

Set zone = Sheets("FICHE").Range("c4:c5")
zone.Copy Sheets("recap").Range("b1")

Set zone = Sheets("FICHE").Range("E4:E5")
zone.Copy Sheets("recap").Range("b3")

Set zone = Sheets("FICHE").Range("c9")
zone.Copy Sheets("recap").Range("b5")

Set zone = Sheets("FICHE").Range("E9")
zone.Copy Sheets("recap").Range("b6")

Set zone = Sheets("FICHE").Range("c12:c15")
zone.Copy Sheets("recap").Range("b7")

Set zone = Sheets("FICHE").Range("E12:E15")
zone.Copy Sheets("recap").Range("b11")

Set zone = Sheets("FICHE").Range("c18")
zone.Copy Sheets("recap").Range("b15")

Set zone = Sheets("FICHE").Range("E18")
zone.Copy Sheets("recap").Range("b16")

Set zone = Sheets("FICHE").Range("C21")
zone.Copy Sheets("recap").Range("b17")

Set zone = Sheets("FICHE").Range("E21")
zone.Copy Sheets("recap").Range("18")

'effacement des données
Sheets("FICHE").Select
[c4:c5].ClearContents
[E4:E5].ClearContents
[C9].ClearContents
[e9].ClearContents
[c12:c15].ClearContents
[e12:e15].ClearContents
[c18].ClearContents
[e18].ClearContents
[c21].ClearContents
[e21].ClearContents


End Sub

Bonjour,

Parmi ces cellules dans FICHE, certaines sont-elles fusionnées ?

Un exemple permettrait de mieux comprendre ce que vous souhaitez.

bonjour

merci de votre réponse mais je n'ai aucune cellule.

le soucis réside sur le fait que je veut décaler ma ligne dans RECAP d'une colonne à chaque nouvelle saisie

A tester :

Sub Ventilation()

Dim ColRecap As Integer
Dim ShFiche As Worksheet, ShRecap As Worksheet

    Set ShFiche = Sheets("FICHE")
    Set ShRecap = Sheets("recap")

    With ShRecap
         ColRecap = .Cells(1, .Columns.Count).End(xlToLeft).Column + 1
    End With

    With ShFiche

         .Range("C4:C5").Copy ShRecap.Cells(1, ColRecap)
         .Range("E4:E5").Copy ShRecap.Cells(3, ColRecap)
         .Range("C9").Copy ShRecap.Cells(5, ColRecap)
         .Range("E9").Copy ShRecap.Cells(6, ColRecap)
         .Range("C12:C15").Copy ShRecap.Cells(7, ColRecap)
         .Range("E12:E15").Copy ShRecap.Cells(11, ColRecap)
         .Range("C18").Copy ShRecap.Cells(15, ColRecap)
         .Range("E18").Copy ShRecap.Cells(16, ColRecap)
         .Range("C21").Copy ShRecap.Cells(17, ColRecap)
         .Range("E21").Copy ShRecap.Cells(18, ColRecap)

         .Range("C4:C5").ClearContents
         .Range("E4:E5").ClearContents
         .Range("C9").ClearContents
         .Range("E9").ClearContents
         .Range("C12:C15").ClearContents
         .Range("E12:E15").ClearContents
         .Range("C18").ClearContents
         .Range("E18").ClearContents
         .Range("C21").ClearContents
         .Range("E21").ClearContents

     End With

     Set ShFiche = Nothing: Set ShRecap = Nothing

End Sub

Quelle honte !

Sub Ventilation2()

Dim I As Integer, ColRecap As Integer
Dim ShFiche As Worksheet, ShRecap As Worksheet
Dim TabFiche As Variant, TabRecap As Variant

    TabFiche = Array("C4:C5", "E4:E5", "C9", "E9", "C12:C15", "E12:E15", "C18", "E18", "C21", "E21")
    TabRecap = Array(1, 3, 5, 6, 7, 11, 15, 16, 17, 18)

    Set ShFiche = Sheets("FICHE")
    Set ShRecap = Sheets("recap")

    With ShRecap
         ColRecap = .Cells(1, .Columns.Count).End(xlToLeft).Column + 1
    End With

    With ShFiche
         For I = LBound(TabFiche) To UBound(TabFiche)
            .Range(TabFiche(I)).Copy ShRecap.Cells(TabRecap(I), ColRecap)
            .Range(TabFiche(I)).ClearContents
          Next I
    End With

    Set ShFiche = Nothing
    Set ShRecap = Nothing

End Sub