Exécution Macro en fonction d'un critère

Bonjour à tous,

Je suis en train de réaliser un code VBA qui me permettra de masquer des colonnes en fonction d'un critères présent dans une table de correspondance, nous retrouvons ce même critère sur l'ensemble des feuilles en ligne 2.

J'ai réussi à créer mon code pour que ce dernier s'exécute comme je le souhaite lorsque je sélectionne une feuille unique.

Cependant je ne parviens à lui affecter une cellule précise dans une feuille.

je voudrais que sur la ligne If.value le critère soit en permanence le suivant : la cellule i4 dans la feuille param

voici mon code :

Sub test()

Dim i As Variant
Application.ScreenUpdating = False
For Each Ws In Worksheets
Ws.Select

[C1:E1].EntireColumn.Hidden = False
For col = 2 To 50
With Cells(1, col)
If .Value = [A1] Then Columns(col).Hidden = True
End With
Next col
Next Ws
Application.ScreenUpdating = True
End Sub

Pouvez-vous m'aider à ajuster ce paramètre ?

Merci par avance pour votre aide.

Bonjour,

Pourquoi traiter jusqu'à la colonne 50 alors que visiblement ce sont les colonnes C à E qui sont concernées ?

Option Explicit

Sub Test()

Dim Col As Integer
Dim ValeurTest As Variant
Dim Ws As Worksheet

    ValeurTest = Sheets("param").Range("A1")
    Application.ScreenUpdating = False
    For Each Ws In Worksheets
        Select Case Ws.Name
             Case "param"

             Case Else
                    With Ws
                         .Range("C1:E1").EntireColumn.Hidden = False
                        For Col = 50 To 2 Step -1
                            With .Cells(1, Col)
                                 If .Value = ValeurTest Then Ws.Columns(Col).Hidden = True
                            End With
                         Next Col
                    End With
         End Select
    Next Ws
    Application.ScreenUpdating = True

End Sub

Merci Eric,

Le code fonctionne comme je le voulais.

pour répondre à ta question j'ai sélectionné jusqu'à la colonne 50 car dans l'utilisation du codes dans les différents fichier je vais en avoir besoin la sélection uniquement sur les colonnes C à E c'était pour réaliser mon test.

bonne journée