Consolider plusieurs onglets sur une feuille

Bonjour,

J'aurais besoin d'un coup de main pour mon fichier.

Je voudrais additionner le résultat de certaines cellules de plusieurs feuilles dans une seule cellule d'une autre feuille.

En clair, enfin je pense:

Collationner les valeurs "positives" dans les cellules"E7 à E37" et "G7 à G37" des différentes feuilles pour les additionner dans les cellules VERTES de la feuille " Bilan Financier 2022" et ça par rapport à leur codes se trouvant dans la colonne "B"

Collationner les valeurs "négatives" dans les cellules "F7 à F37" et "H7 à H37" des différentes feuilles pour les additionner dans les cellules JAUNES de la feuille " Bilan Financier 2022" et ça par rapport à leurs codes se trouvant dans les colonnes "B"

J'ai essayé avec la fonction =SOMME.SI.ENS mais je n'arrive pas à faire vraiment ce que je voudrais.

Du VBA ou des formules, je n'ai aucun préjugé.

Un fichier pour plus de clarté

Merci à vous

Bonjour Bayard

Vu le nombre de feuilles et de colonnes à additionner, une petite fonction personnalisée en VBA pourrait être pas mal

Function Total(Code)
  Dim dLig As Long, Lig As Long
  Dim Sht As Worksheet
  ' Recalculer à chaque modification
  Application.Volatile
  ' Pour chaque feuille
  For Each Sht In ThisWorkbook.Sheets
    ' Si ce n'est pas la feuille de bilan elle même
    If InStr(1, Sht.Name, "bilan", vbTextCompare) = 0 Then
      ' Dernière ligen remplie de la colonne B
      dLig = Sht.Range("B" & Rows.Count).End(xlUp).Row
      ' Pour chaque ligne
      For Lig = 6 To dLig
        ' Si le code correspond
        If Sht.Range("B" & Lig) = Code Then
          ' Faire le total de la ligne
          Total = Total + Application.Sum(Sht.Range("I" & Lig & ":W" & Lig))
        End If
      Next Lig
    End If
  Next Sht
End Function

Voici le fichier avec la fonction personnalisée

A+

C'est tout bonnement parfait

Je te remercie pour ton travail et bonne journée!

je teste tout ça et je clôture ensuite!