Supprimer le macro et le bouton pendant le sauvegarde

Bonjour

se macro sauvegarde le fichier .xlsm en .xlsx

Sub Button15_Click()
   Application.DisplayAlerts = False
' Sauvegarder un fichier xlsm en xlsx debut
   nf = [C2].Value
   sChemin = ThisWorkbook.Path
   With Application.FileDialog(msoFileDialogFolderPicker)
      .InitialFileName = sChemin & "\"
      .Title = "Sélectionner le dossier de destination ..."
      .AllowMultiSelect = False
      .InitialView = msoFileDialogViewDetails
      .ButtonName = "Sélection destination"
      .Show
      If .SelectedItems.Count > 0 Then
         Destination = .SelectedItems(1) & "\"   ''
      End If
   End With
   Application.EnableEvents = False
   With ActiveSheet
      .Copy
      With ActiveWorkbook   
         .SaveAs Filename:=Destination & nf, FileFormat:=xlOpenXMLWorkbook
         .Close
      End With
   End With
   Application.EnableEvents = True
End Sub

je veux que vous m'aidiez pour ajouter un code adapter avec se macro, qui supprimera le macro et le bouton pendant le sauvegarde du fichier .xlsx

merci

Bonjour,
Une proposition à adapter !?
Cdlt.

Public Sub Button15_Click()
Dim nf As String, sChemin As String, sDestination As String, n As Long

    sChemin = ThisWorkbook.Path & Application.PathSeparator
    nf = [C2].Value & ".xlsx"
    n = Application.SheetsInNewWorkbook

    With Application.FileDialog(msoFileDialogFolderPicker)
        .InitialFileName = sChemin
        .Title = "Sélectionner le dossier de destination ..."
        .AllowMultiSelect = False
        .InitialView = msoFileDialogViewDetails
        .ButtonName = "Sélection destination"
        .Show
        If .SelectedItems.Count > 0 Then
            Application.DisplayAlerts = False
            sDestination = .SelectedItems(1) & Application.PathSeparator
            With ActiveSheet
                .Copy
                With ActiveWorkbook
                    .Worksheets(1).Shapes.Range(Array("Button 1")).Delete
                    .SaveAs Filename:=sDestination & nf, FileFormat:=xlOpenXMLWorkbook
                    .Close
                End With
            End With
        End If
    End With

    Application.SheetsInNewWorkbook = n

End Sub