Afficher Msgbox de 07h00 à 08h00

Bonjour tout le monde,

J'ai un classeur "TDB" qui contient une seule feuille qui se nomme "ACCUEIL PILOTE RESTAURATION" .

J'aimerai que tous les matins à chaque ouverture de ce classeur, il m'affiche un UserForm "INFORMATION_JOUR" de 06h30 à 08h00 pour me rappeler une tâche qui doit être faite tous les matins. Une fois 08h30 passé il ne doit plus s'afficher.

J'ai réussi à le faire afficher, en plaçant le texte dans "thisworkbook" mais en ce qui concerne le texte pour programmer les plages horaires je trébuche.....

Auriez-vous un peu de temps pour moi SVP.

Je vous Remercie d'avance

Cordialement, Rubis5460

Bonjour,

Pas tout compris. Si le message ne doit plus s'afficher à partir de 8h30, la plage devrait être 6h30-8h30 au lieu de 6h30-8h00.

bonjour Optimix

Oups ! désolé, c'est bien de 06h30 à 08h00 et après 08h00 il ne doit plus s'afficher.

Merci

J'ai mis mon message d'alerte dans la cellule B1.

Option Explicit

Private Sub Workbook_Open()
    Dim time1, time2

    time1 = TimeValue("06:30:00 AM")
    time2 = TimeValue("08:00:00 AM")

    If time1 < Time And time2 > Time Then MsgBox Cells(1, 2)
End Sub

Merci Optimix

mais je n'ai pas compris ton "J'ai mis mon message d'alerte dans la cellule B1."

moi je voulais mettre un texte a moi dans le msgbox, donc je vais le changer.

Bonjour le Fil

Pour moi, c'est un peu plus complexe que ça, non

Voici mon fichier USF se lancera si on ouvre le fichier à 17h45 ou un peu après
Nota : le titre "Msgbox" ne correspond pas à la demande " il m'affiche un UserForm "INFORMATION_JOUR""

Texte à mette dans

Me.Label1.Caption = "Mon texte"

Dans "UserForm1_Initialise()"

A+

OK ! Je suis vraiment nul ce week-end !!

je fais pas attention du tout.

Merci Optimix j'ai compris. Je te tiens au courant demain après le test demain matin.

Bonne soirée

Cordialement Rubis5460

En plus je me trompe de nom en te répondant !

il va falloir que j'arrête pour aujourd'hui. Trop c'est trop

Merci Bruno

A demain

Re

Dans mon fichier que je viens de modifier pour demain matin du coup

J'ai un module ou tu fixes l'heure de début et de fin de l'affichage de l'USF

Option Explicit

Public MemWhen
Public Const Hdeb As String = "06:30:00"
Public Const Hfin As String = "08:00:00"

Sub StartTimer(When, What)
  ' Lancer le timer
  Application.OnTime TimeValue(When), What
  MemWhen = When
End Sub

Sub StopTimer()
  On Error Resume Next
  ' Stoppe la procédure dans le délai
  Application.OnTime MemWhen, Procedure:="", Schedule:=False
  On Error GoTo 0
End Sub

Sub OuvrirUSF()
 UserForm1.Show False
 Call StartTimer(Hfin, "FermerUSF")
End Sub

Sub FermerUSF()
  Unload UserForm1
  Call StopTimer
End Sub

Ensuite j'ai un code dans ThisWorkbook, qui vérifie à quelle heure est ouvert le fichier
Et s'il est ouvert entre l'heure de début et l'heure de fin, lance l'USF et le Timer

Private Sub Workbook_Open()
  If TimeValue(Now) <= TimeValue(Hdeb) Then
    Call StartTimer(Hdeb, "OuvrirUSF")
  Else  ' L'heure est dépassée, on affiche l'USF et on lance le timer de fermeture
    ' Vérifier si l'heure de fin n'est pas dépassée
    If TimeValue(Now) > TimeValue(Hfin) Then
      ' Si oui, on ne fait plus rien
    Else
      ' Ouvrir seulement l'USF (le timer de fermeutre sera lancé)
      Call OuvrirUSF
    End If
  End If
End Sub

A+

Bonjour Bruno, Bonjour Optimix,

Optimix, Merci pour ce VBA qui fonctionne, mais j'ai mis en place le code de Bruno.

Bruno, aujourd'hui ça va mieux J'ai mis ton code en place et tout fonctionne très bien.

Merci à toi pour ce joli travail.

Bon dimanche et A+

Bonjour,

C'est souvent ça, une bonne nuit de sommeil, un bon café et ça repart

Sinon de rien, avec plaisir