Erreur compilation avec msgBox et variable

Bonjour,

J'ai écrit ce code pour afficher la ligne où se trouve une valeur recherché mais quand j'écrit ce code le message d'erreur de compilation s'affiche et je ne comprend pas pourquoi.

Dim numdemande As Integer
Dim DernLigne As Integer
Dim C As Long

numdemande = InputBox("quel numero de demande")

DernLigne = Feuil5.Range("B" & Rows.Count).End(xlUp).Row

C = Feuil5.Range("B1:B" & DernLigne).Find(What:=numdemande, LookIn:=xlValues)

MsgBox ("la ligne est" & C.Row)

Quelqu'un peut-il m'aider à comprendre l'erreur svp?

merci d'avance

Bonjour,
Une proposition.
Cdlt.

Public Sub SearchRow()
Dim lastRow As Long, rng As Range, Answer As String, rw
    Answer = InputBox("quel numero de demande")
    If StrPtr(Answer) <> 0 And Answer <> "" Then
        With ActiveSheet
            lastRow = .Cells(.Rows.Count, 2).End(xlUp).Row
            Set rng = .Cells(1, 2).Resize(lastRow)
            On Error Resume Next
            rw = Application.Match(CLng(Answer), rng, 0)
            If Not IsError(rw) Then
                MsgBox rw
            Else
                MsgBox "la valeur " & Answer & " n'existe pas."
            End If
        End With
    End If
End Sub

Merci beaucoup cela fonctionne que je le voulais