Copier dipositives Powerpoint vers Excel

Bonjour la communauté,

Je voudrai copier les diapositives d'un powerpoint vers un fichier excel. Je n'arrive pas à configurer VBA pour qu'il puisse dialoguer avec powerpoint.

J'ai deja coché la case dans: Outils>références> Microsoft Powerpoint 16.0 Object Library mais il me renvoit toujour des erreurs..

Ce que je voudrai faire c'est:

Pour chaque slide, la copier dans une nouvelle feuille excel.

For i = 1 To 99

ActivePresentation.Slides(i).Copy
ActiveSheet.Past
Sheets.Add After:=ActiveSheet
Sheets(i+1).Select

Next

End Sub

Quelqu'un a t'il une solution?

Merci d'avance!

Bonjour,

ci-dessous exemple de code :

Sub Importation_diapos()

    Dim nom_fichier As String, fichier As Object
    Dim ppt_pres As PowerPoint.Presentation, diapo As PowerPoint.Slide

    'Affiche la boîte de dialogue "Ouvrir"
    nom_fichier = Application.GetOpenFilename("fichiers PowerPoint *.ppt*,")

    'Sortie si annulation
    If nom_fichier = "Faux" Or nom_fichier = Empty Then MsgBox "aucun fichier sélectionné": Exit Sub

    'Assigne le fichier ouvert et vérifie que c'est une présentation PowerPoint
    Set fichier = GetObject(nom_fichier)
    If Not fichier.Application.Name Like "*PowerPoint" Then MsgBox "fichier ouvert non PowerPoint": fichier.Close: Exit Sub
    Set ppt_pres = fichier

    'Copie les diapos dans le classeur
    For Each diapo In ppt_pres.Slides
        diapo.Copy
        ActiveSheet.Paste
        Sheets.Add After:=ActiveSheet
    Next diapo

    'Ferme l'application PowerPoint
    ppt_pres.Application.Quit

End Sub

C'est exactement ce qu'il me fallais!

Merci beaucoup!