Copier-coller à la suite - VBA

Bonjour a tous,

Je ne suis pas un spécialiste de VBA je vous demande de l'aider sur un probleme.

Je m’explique j’ai un script écrit dans l’onglet »CODE » de B3 à B27, il faudrait le copie dans l’onglet « RESULTAT » mais à la place ‘1;#NOMDWGTOUT#’ il faudrait mettre le chemin du Chemin qui se situe dans l’onglet « CopieDeProjet », et refaire la copie du script ainsi de suite suivant le nombre de chemin présent dans l’onglet « CopieDeProjet »

Est-ce bien clair ?

Est-ce possible en VBA si possible ?

J’ai mis un début de résultat mais sans formule pour aider…

Bonjour,

a tester:

Sub CopieScript()
Dim TC, TCP, i As Long, Lig As Long
With Worksheets("Code")
TC = .Range("B3:B" & .Range("B" & Rows.Count).End(xlUp).Row)
End With
With Worksheets("CopieDeProjet")
TCP = .Range("A1:A" & .Range("A" & Rows.Count).End(xlUp).Row)
End With
Lig = 1
For i = LBound(TCP, 1) To UBound(TCP, 1)
    TC(2, 1) = TCP(i, 1)
    With Worksheets("Resultat")
    .Range("B" & Lig).Resize(UBound(TC, 1), 1) = TC
    End With
    Lig = Lig + UBound(TC, 1)
Next
MsgBox "Terminé"
End Sub

A+

Un grand merci cela fonctionne.

Pouvez-vous simplement dire si c'est possible de faire une macro pour faire un enregistrer sous "txt" de l'onglet résultat puis ensuite de modifier l’extension du fichier créer

merci pour votre aide

Plutôt que d'écrire dans une feuille, puis exporter cette feuille en fichier texte puis modifier l'extension du fichier, je vous propose de sortir directement un fichier texte avec l'extension désirée:

Sub CopieScript()
Dim TC, TCP, i As Long, j As Long
With Worksheets("Code")
TC = .Range("B3:B" & .Range("B" & Rows.Count).End(xlUp).Row)
End With
With Worksheets("CopieDeProjet")
TCP = .Range("A1:A" & .Range("A" & Rows.Count).End(xlUp).Row)
End With
' Crée et Ouvre le fichier en écriture. Adapter le chemin et le nom du fichier:
Open "C:\.....\...\....\FICHTEST.lulu" For Output As #1   

For i = LBound(TCP, 1) To UBound(TCP, 1)
    TC(2, 1) = TCP(i, 1)
    For j = LBound(TC, 1) To UBound(TC, 1)
        Print #1, TC(j, 1)
    Next
Next
Close #1
MsgBox "Terminé"
End Sub

Merci, Merci, est-ce possible d'afficher le nom du répertoire ou l’enregistrer et choisir le nom du fichier?