Code VBA pour fusion des fichiers pdf dans deux dossiers différents

Bonjour,

J'ai deux dossiers qui contiennent des fichiers pdf.

Quelqu'un pourrait m'aider à développer un code VBA sur excel pour fusionner deux fichiers pdf de même nom venant des deux dossiers.

Merci de votre aide

Bonjour Serigne et

Une petite présentation ICI serait la bienvenue

Si vous ne l'avez pas encore fait, je vous invite à lire la charte du forum [A LIRE AVANT DE POSTER]
qui vous aidera dans vos demandes et réponses sur ce forum

Merci de votre participation

Cordialement

Bonjour Bruno,

Merci pour les éclaircissements.

charte déjà lu.

Par rapport à la présentation, je sais pas exactement où la faire.

Pouvez-vous m'aider ?

Re,

Il y a juste à cliquer sur le "ICI" de mon post précédent

Sinon quelle est l'application utilisée pour visualiser les PDF ?
Et quand vous parlez de fusionner, c'est mettre la page de l'un des documents dans l'autre ?

@+

Bonjour,

Au fait j'utilise Adobe Acrobat Reader, pdf reader, Microsoft Edge, etc.

Je parle de mettre un document entier ensemble avec un autre trouvant dans un autre dossier.

Re,

Si vous n'avez que des versions Reader, pour moi ce n'est pas possible de fusionner 2 documents PDF

A ma connaissance, l'édition sur Edge arrive, mais n'est pas encore présente et sera certainement payante (comment reste la question)

@+

Si je comprends bien ce n'est pas possible avec excel.

Bonjour Serigne, salut BrunoM45 et le Forum,

pour fusionner des fichiers pdf à partir d'excel, j'utilise normalement PDFtk Server, téléchargeable gratuitement via ce lien https://www.pdflabs.com/tools/pdftk-server/

Voici un exemple de code, à adapter le chemin où se trouvent les fichiers PDF et éventuellement le chemin d'installation de PDFTK

Sub FusionPDF()

Dim strParam As String, RetVal As String, F1 As String, F2 As String, F3 As String

F1 = "C:\Users\Sequoyah\Desktop\Forum\A\Charlie.pdf" ' Premier fichier
F2 = "C:\Users\Sequoyah\Desktop\Forum\B\Charlie.pdf" ' deuxième fichier
F3 = "C:\Users\Sequoyah\Desktop\Forum\Test.pdf" ' output

strParam = "A=" & F1 & " " & "B=" & F2 & " cat A B output " & F3

RetVal = Shell("C:\Program Files (x86)\PDFtk\bin\Pdftk.exe " & strParam, 0)

End Sub

Cordialement

Bonjour et merci @Sequoyah pour l'info

Je ne connaissais pas... je dormirai moins bête ce soir

Bonjour tout le monde,

voici le code qui devrait faire exactement ce que Serigne a demandé :

Sub FusionPDF2()

    Dim oFSO As Object, oFolder As Object, oFile As Object
    Dim sPath1 As String, sPath2 As String, sPath3 As String
    Dim strParam As String, RetVal As String, F1 As String, F2 As String, F3 As String

    sPath1 = "C:\Users\Sequoyah\Desktop\Forum\A un\"
    sPath2 = "C:\Users\Sequoyah\Desktop\Forum\B deux\"
    sPath3 = "C:\Users\\Sequoyah\Desktop\Forum\C trois\"

    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Set oFolder = oFSO.GetFolder(sPath1)

    For Each oFile In oFolder.Files

        F1 = sPath1 & oFile.Name
        F2 = sPath2 & oFile.Name
        F3 = sPath3 & oFile.Name

        F1 = """" & F1 & """"
        F2 = """" & F2 & """"
        F3 = """" & F3 & """"

        strParam = "A=" & F1 & " " & "B=" & F2 & " cat A B output " & F3

        RetVal = Shell("C:\Program Files (x86)\PDFtk\bin\Pdftk.exe " & strParam, 0)

    Next oFile

    Set oFile = Nothing
    Set oFolder = Nothing
    Set oFSO = Nothing

End Sub