VBA procédures à reproduire 80 fois

Bonjour à toutes et à tous,

Voici mon pb:

j'ai un userform dans lequel j'ai 80 images nommées de image1 à image80.

Je veux que lorsqu'on clique sur une image une procédure se lance automatiquement, c'est toujours la même procédure, il y a juste le nom de la photo qui change...

Comment écrire 80 fois la même chose en peu de temps ? j'ai essayé en les sélectionnant toutes mais ça ne fait rien... et j'ai la flemme de le faire 80 fois...

D'avance merci...

j'espère avoir été clair...

A+

Souri84

EDIT 2: et aussi comment fait-on bouger les images ? j'ai essayé avec par exemple

image80.move 1, 100

mais mon image ne bouge pas ^^... et j'aimerai la déplacer dans une frame située en haut à gauche de mon userform...

je ne peux pas joindre de fichier, je suis au boulot et mon accès est restreint...

d'avance merci,

Souri84

bonjour

en utilisant un module de classe :

'--------------------------------------
'dans un module standard
Option Explicit

Public Collect As Collection
'--------------------------------------

'--------------------------------------
'dans un module de classe nommé "Classe1"
'
Option Explicit

Public WithEvents Img As MSForms.Image

'exemple pour gerer l'evenement clic sur les objets type Image
Private Sub Img_Click()
    'cet exemple affiche le nom de l'objet cliqué
    MsgBox Img.Name
End Sub
'--------------------------------------

'--------------------------------------
'Dans le module objet du UserForm

Private Sub UserForm_Initialize()
    Dim Obj As Control
    Dim Cl As Classe1

    Set Collect = New Collection

    For Each Obj In Me.Controls
        'verifie s'il s'agit d'un objet Image
        If TypeOf Obj Is MSForms.Image Then
        Set Cl = New Classe1
        Set Cl.Img = Obj
        Collect.Add Cl
        End If
    Next Obj

End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    Set Collect = Nothing
End Sub
'--------------------------------------

bonne soirée

michel

je vais tester cela tout a l'heure,

merci beaucoup,

Souri84