Tri de plusieurs tableaux dans la même feuille

Bonjour,

Je tente désespérément de créer une macro me permettant de trier plusieurs tableaux dans la même feuille.

Dans mon fichier, je souhaite que la macro puisse identifier toutes les cellules jusqu'à la première ligne vide puis de les trier par type.

Par la suite, que la cellule qui correspond au type bbb soit en couleur.

Pouvez-vous m'aider SVP ?

Merci par avance et très bonne journée.

Cordialement,

bonjour LSP,

le couleur est fait avec une MFC (mise en format conditionelle)

la macro

Sub Trier()
     With Sheets("AXG_Contactlist").Columns("A") 'colonne A de cette feuille
          Set c = .Find("Prénom", lookat:=xlWhole) 'rechercher une cellule avec "Prénom"
          If Not c Is Nothing Then 'trouvé
               fa = c.Address 'adresse de la premièe cellule trouvée
               Do 'boucle
                    Set c1 = c.CurrentRegion 'la plage autour
                    With c.Resize(c1.Rows.Count + c1.Row - c.Row, 5) 'la plage du "tableau"
                         .Sort .Range("E1"), Header:=xlYes 'trier tableau par type
                    End With
                    Set c = .FindNext(c) 'rechercher prochaine cellule "prénom"
                    b = Not c Is Nothing 'trouvé
                    If b Then b = (c.Address <> fa) 'ce n'est pas la première
               Loop While b
          End If
     End With
End Sub

Bonjour,
Une première seconde proposition.
Les données sont sous forme de tableaux structurés avec une MFC pour le type bbb.
ALT F8 puis exécuter SortData.
Cdlt.

Public Sub SortData()
Dim ws As Worksheet, lo As ListObject
    Application.ScreenUpdating = False
    Set ws = Worksheets("AXG_ContactList")
    For Each lo In ws.ListObjects
        With lo.Sort
            .SortFields.Add Key:=lo.ListColumns(5).DataBodyRange
            .Header = xlYes
            .Apply
            .SortFields.Clear
        End With
    Next
End Sub

Bonjour,

Un énorme merci à vous deux :)

ça fonctionne hyper bien ;)

Très bonne journée.