Transformation texte vers date

Bonjour à tous.

Je suis nouveau sur ce forum , je l'ai parcouru , sans trop trouver un solution à mon petit problème .

Voila , je voudrais transformer une suite de caractère au format texte en "date" "heure mn ss "

J'ai : Sun Jan 26 2020 12:40:12

et voudrais obtenir : 26/01/2020 12:40:12 ( jj/mm/aaaa hh:mm:ss)

Ce sera surement facile pour certain d'entre vous de trouver , mais pour moi c'est un peu galère

Merci de vos réponses .

Slts

Bonjour,

Avec la date texte en A2, formule à tester

=DATE(STXT(A2;12;4);MOIS(1&STXT(A2;5;3));STXT(A2;9;2))+TEMPS(STXT(A2;17;2);STXT(A2;20;2);STXT(A2;23;2))

Bonjour,

Une autre proposition.

Cdlt.

=DATE(GAUCHE(DROITE(A1;13);4);
MOIS(EQUIV(STXT(A1;5;3);{"jan";"feb";"mar";"apr";"may";"jun";"jul";"aug";"sep";"oct";"nov";"dec"};0));
STXT(A1;9;2))+DROITE(A1;8)

Bonjour

Merci à M12 et Jean-Eric .

Il a fallu que je change les ";" en "," dans les formules , je ne sais pas pourquoi excel ne prend pas en compte les ";" .

Sinon les 2 formules fonctionnent , a partir du moment où la propriétés des cellules soient correctes .

Un grand merci

Bonsoir

J'ai valider un peu trop vite les solutions proposées , n'ayant essayé que sur 3 valeurs !

Quelques erreurs sont apparues lorsque j'ai voulu appliquer les formules à ma suite de 150 valeurs !

Sun Jan 26 2020 12:40:12 : fonctionne avec les 2 formules OK

Fri Feb 28 2020 15:51:58 : ne fonctionne pas , le mois n'est pas correct ou le résultat se met en défaut ""VALEUR!"

Mon Mar 02 2020 09:19:58

Sun Aug 26 2020 12:40:16

Sun Dec 26 2020 12:40:18

J'ai essayé pas mal de choses , mais je bloque , pourriez vous me venir en aide

Merci

Re,

Les mois étant en anglais, ma formule ne peut fonctionner

En modifiant celle de Jean-Eric, cela devrait fonctionner (Modifie les points virgule pour ta version Excel)

=DATE(GAUCHE(DROITE(A2;13);4);EQUIV(STXT(A2;5;3);{"jan";"feb";"mar";"apr";"may";"jun";"jul";"aug";"sep";"oct";"nov";"dec"};0);STXT(A2;9;2))+DROITE(A2;8)

Bonsoir

Merci , cette formule fonctionne maintenant correctement .

J'ai pris celle de Jean-Eric , dans laquelle le fonction "mois" a été retirée , c'est peut être ça qui bloquait en plus ? (associé au mois anglais)

Encore merci