Transfert d'image entre 2 onglets

Bonjour,

J'ai un problème de transfert automatique de donnés notamment "images" ,

Sous l'onglet "Feuil1" c'est mon tableau de saisie ou je choisi d'abord le service et automatiquement la photo du responsable du service concerné "Cellule F5" (Pilotes )

Après avoir cliquer sur le bouton "Transfert" afin d’insérer la ligne dans l'onglet "feuil2" la photo est mal déplacée et elle n'affiche rien !

Le fichier ci joint explique tout

Merci d'avance pour votre aide

Cordialement

Un petit up pour ma demande d'aide

je suis bloqué

Cordialement

Bonjour,

Essaie ainsi :

1) Modifier la formule référençant logooo dans le Gestionnaire de noms :

=DECALER(Feuil1!$V$11;EQUIV(Feuil1!$E$2;Feuil1!$U$12:$U$13;0);)

2) Pour arranger un peu ta macro enregistrée :

Sub Macro1()
   ActiveSheet.Range("A5:B5,D5:H5").Copy Worksheets("Feuil2").Range("A4")
End Sub

Cordialement.

Bonjour MFerrand !

Génial ! par contre pour l'insertion de ligne dans l'onglet "Feuil2" (à partir de la ligne 5) est ce que c'est possible de tout décaler en bas à chaque transfert de donnés ? afin de créer une base de donnés de toutes les demandes !

Cordialement

S'il s'agit d'insérer une ligne pour pouvoir faire toujours le collage ligne 4, voilà qui le fait :

Sub Macro1()
    With Worksheets("Feuil2")
        ActiveSheet.Range("A5:B5,D5:H5").Copy .Range("A4")
        .Range("A4:G4").Insert xlShiftDown, xlFormatFromRightOrBelow
        .Range("A4:G4").Borders.Weight = xlThin
    End With
End Sub

Mais je vois un problème dans ton système, c'est que tes images sont toutes égales à logooo, et logooo ne représente qu'une seule image, correspondant à la valeur de E2 en Feuil1, c'est à dire que partout ton image sera identique et changera en même temps !

Je ne vois pas trop comment régler ça au niveau de la formule (ou alors de façon compliquée...)...

Je vais essayer d'y réfléchir : si pas d'adaptation simple, il vaudra mieux s'orienter vers du VBA pour l'insertion photo..

Cordialement.

Oui t'as raison j'étais entrain de réfléchir à une solution ...est ce possible de copier la photo (feuil1) et la coller (collage spécial ss forme de photo) mais en respectant le numéro de la ligne à chaque insertion ?

Cordialement

Bonjour,

J'ai fait quelques recherches, sans grand résultat, fait divers petits tests plus ou moins peu concluants ! pour finir par dissocier le transfert du texte, fait par tableau VBA, du transfert de l'image opéré par copie mais sur le tableau source en U12:V13 et collé en image liée à sa source.

C'est en fait la méthode Appareil photo pour l'image, mais il semble que ce soit celle qui donne le meilleur résultat.

Pas de problème à la suite pour insérer une ligne et la mettre en forme pour préparer l'inclusion suivante.

Remarque : l'insertion pourrait être faite avant le transfert, de façon à ne pas avoir une ligne vide permanente...

Mais teste d'abord la méthode...

Sub Macro1()
    Dim Pimg As Range, Img As Object, Lgn(6), i%
    With ActiveSheet
        Set Pimg = .Range("U12:U13")
        Do
            i = i + 1
            If Pimg.Cells(i, 1) = .Range("C5") Then
                Set Pimg = Pimg.Cells(i, 2)
                Exit Do
            End If
        Loop While i < Pimg.Rows.Count
        Lgn(0) = .Cells(5, 1): Lgn(1) = Date
        For i = 4 To 5
            Lgn(i - 2) = .Cells(5, i): Lgn(i + 1) = .Cells(5, i + 3)
        Next i
    End With
    With Worksheets("Feuil2")
        .Range("A4:G4").Value = Lgn
        If Pimg.Cells.Count = 1 Then
            Pimg.Copy
            Set Img = .Pictures.Paste(True)
            Application.CutCopyMode = False
            With .Range("E4")
                Img.Left = .Left: Img.Top = .Top + .Height / 2 - Img.Height / 2
            End With
        End If
        .Range("A4:G4").Insert xlShiftDown, xlFormatFromRightOrBelow
        With .Range("A4:G4")
            .Borders.Weight = xlThin
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlCenter
            .WrapText = True
        End With
    End With
End Sub

Cordialement.

Bonjour MFerrand

Franchement je trouve pas les mots pour te remercier, c'est génial ce que tu m'as proposé

merci infiniment

Bonjour,

Pour éviter d'avoir une ligne vide sur Feuil2, il faudrait modifier ainsi la 3e partie du code :

   [...]
    End With
    With Worksheets("Feuil2")
        .Range("A4:G4").Insert xlShiftDown, xlFormatFromRightOrBelow
        With .Range("A4:G4")
            .Borders.Weight = xlThin
            .HorizontalAlignment = xlCenter
            .VerticalAlignment = xlCenter
            .WrapText = True
            .Value = Lgn
        End With
        If Pimg.Cells.Count = 1 Then
            Pimg.Copy
            Set Img = .Pictures.Paste(True)
            Application.CutCopyMode = False
            With .Range("E4")
                Img.Left = .Left: Img.Top = .Top + .Height / 2 - Img.Height / 2
            End With
        End If
    End With
End Sub

L'insertion se fera alors lors du transfert...

Cordialement.