Supprimer lignes si absence de codes

Bonjour à vous,

Je travaille actuellement sur une base de données où les noms sont remplacés par des codes type "335487".

Je dois travailler seulement sur les lignes qui contiennent un code parmi une liste à part, et donc je souhaiterai supprimer les lignes qui ne contiennent pas un des codes de cette liste. Je vous mets ci-joint un exemple de ce que je souhaiterai faire (passer du "tableau 1" au "tableau 2" en supprimant toutes les lignes qui ne comportent pas un des codes indiqués).

Pouvez-vous, s'il vous plaît, m'indiquer la marche à suivre ?

N'hésitez pas si ma demande n'est pas claire.

Cordialement.

Salut Léo, et bienvenue sur ce Forum!

Tu trouveras ci-joint ton fichier modifié, avec en feuille 2, un bouton permettant de supprimer les lignes n'ayant pas le code demandé!

La seule chose qui me gêne, c'est de savoir si la disposition de ta colonne contenant "les codes à garder" restera la même ou non :p

Restant à dispo!

Bonjour Juice,

Merci pour votre réponse très rapide, c'est exactement ce que je souhaitais faire. Quelle manipulation/fonction avez-vous utilisée pour arriver à cela ? Une macro d'après ce que je vois mais je ne les maîtrise pas.

Non vu la taille du fichier que j'ai, je comptais mettre cette série de code sur une autre feuille cela a-t-il des conséquences ?

En vous remerciant.

Reee~

Ravie que cela convienne à ta demande ;D

LeoS a écrit :

Quelle manipulation/fonction avez-vous utilisée pour arriver à cela ? Une macro d'après ce que je vois mais je ne les maîtrise pas.

Alors en effet, j'ai bien utilisé une macro. Code ci-dessous :

Sub SuppCode()
Dim Supp As Integer
Dim x As Long, y As Long
For x = 3 To Range("A" & Rows.Count).End(xlUp).Row
    Supp = 1
    For y = 3 To Range("G" & Rows.Count).End(xlUp).Row
        If Cells(x, 1) = Cells(y, 7) Then Supp = 0
    Next
    If Supp = 1 Then Range("A" & x & ":C" & x).ClearContents
Next
Columns("A:C").SpecialCells(xlCellTypeBlanks).Delete Shift:=xlUp
End Sub

En gros, pour chaque x ligne de ma colonne A, je teste si le code est présent sur l'une des lignes y a de ma colonne G (où les codes à gardés sont renseignées)

Si ce n'est pas la cas, alors je supprime la ligne x (via ClearContents) et quand toutes les lignes x ont été testées, je supprime les lignes vides.

LeoS a écrit :

Non vu la taille du fichier que j'ai, je comptais mettre cette série de code sur une autre feuille cela a-t-il des conséquences ?

Alors en effet cela aura des conséquences.

Il faut que les références indiquées dans un code reste fixe.

Le mieux serait que tu me dise dans quelle colonne tu souhaite mettre ta liste de "code à garder" pour que je change mon code, et que sa ne bouge plus ensuite :p

Restant à dispo!

Bonjour,

Une autre proposition.

Cdlt.

Public Sub Clean_data()
Dim lo As ListObject, lo2 As ListObject
Dim Cell As Range, r As Range, rng As Range
    With ActiveSheet
        Set lo = .ListObjects("Tableau1")
        Set lo2 = .ListObjects("Tableau2")
        For Each Cell In lo.ListColumns(1).DataBodyRange
            Set r = lo2.ListColumns(1).DataBodyRange.Find(Cell.Value, LookIn:=xlValues, lookat:=xlWhole)
            If r Is Nothing Then
                If rng Is Nothing Then
                    Set rng = Cell.Resize(, lo.ListColumns.Count)
                Else
                    Set rng = Union(rng, Cell.Resize(, lo.ListColumns.Count))
                End If
            End If
        Next Cell
        If Not rng Is Nothing Then rng.Delete
    End With
End Sub

(Re)bonjour à vous,

J'ai essayé d'appliquer vos codes en changeant certaines choses (les lettres des colonnes sur le code de Juicy et en créant des tableaux pour le code de Jean-Eric). Toutes les lignes ont été supprimées même celles possédant un des "codes à garder".

Pour Juicy, mon tableau va de la colonne A (où il y a les codes) à la colonne N, j'ai positionné ma liste de codes à garder sur la colonne P.

Je vous remercie pour votre aide.

Reeee~

Salut Jean-Eric!

@Léo,

Tu trouveras ci-joint ton code modifié qui correspond à la mise en forme indiquée dans ton précèdent message.

Restant à ta dispo

Merci beaucoup Juice, ton code fonctionne

Re,

Désolé, mais cela fonctionne !...

Cdlt.