Sélection de feuilles Excel en Pdf Renommé

Bonsoir

Voila la situation: J'ai un fichier excel où j'ai pu instaurer une macro d’édition en Pdf.

J'ai trouvé ce code sur des forums que j'ai adapté à mes besoins: Edition des feuilles "Print1", " Print2" et "Print3" en pdf.

C'est un code qui marche très bien seulement je veux que le nom du fichier Pdf soit la combinaison du contenu de trois cellules de la feuille "Print1" exactement D1, B2 et B3 dans cet ordre sachant que se sont des cellules alimentées par des formules.

Mon deuxième souci c'est que ce fichier Pdf s'enregistre sur un chemin particulier que je n'arrive pas à changer, j'aimerais que l'enregistrement se fasse automatiquement sur le bureau.

J’espère que j'ai bien expliqué le problème et merci pour vos aides qui m'ont toujours été utiles.

Private Sub CommandButton1_Click()

Dim sRep As String

Dim sFilename As String

Sheets(Array("Print1", "Print2", "Print3")).Select

sRep = ThisWorkbook.Path

sFilename = ThisWorkbook.Name

sFilename = Left(sFilename, InStr(1, sFilename, ".")) & "pdf"

ActiveSheet.ExportAsFixedFormat _

Type:=xlTypePDF, _

Filename:=sRep & sFilename, _

Quality:=xlQualityStandard, _

IncludeDocProperties:=True, _

IgnorePrintAreas:=False, _

OpenAfterPublish:=True

End Sub

Tu dois donc changer ces lignes :

sRep = ThisWorkbook.Path
sFilename = ThisWorkbook.Name
sFilename = Left(sFilename, InStr(1, sFilename, ".")) & "pdf"

par

sRep = ObtenirCheminBureau & "/"
sFilename = Sheets("Print1").range("D1") &  Sheets("Print1").range("B2") &  Sheets("Print1").range("B3") & "pdf"

à tester (car sans fichier je travaille sans filet !)

avec cette procédure à ajouter :

Public Function ObtenirCheminBureau() As String
    On Error GoTo ObtenirCheminBureauError
    Dim CheminBureau As String
    CheminBureau = ""
    Dim oWSHShell As Object
    Set oWSHShell = CreateObject("WScript.Shell")

    CheminBureau = oWSHShell.SpecialFolders("Desktop")

    If (Not (oWSHShell Is Nothing)) Then Set oWSHShell = Nothing
    ObtenirCheminBureau = CheminBureau

    Exit Function
ObtenirCheminBureauError:
    If (Not (oWSHShell Is Nothing)) Then Set oWSHShell = Nothing
    ObtenirCheminBureau = ""
End Function

Bonsoir,

Merci pour votre réponse rapide mais surtout efficace. C'est exactement ce que je voulais.

J'ai juste rajouter des &"-"& entre les noms des cellules pour que le nom du fichier Pdf soit lisible.

Donc Merci et je passe en résolue