Scindé le contenu de cellule
Bonjour à tous,
Est-il possible de décortiquer dans plusieurs cellules un phrase?
Exemp : "24, rue juliette DODU 97480 Saint-Joseph" dans une cellule
pouvoir scindé cette adresse en 2 ou 3 cellules pour donner exp
cellule1 : 24, rue Juliette DODU
Cellule2 : 97480
cellule3 : Saint-Joseph
Si c'est possible je serai très satisfait. Cela m'éviterai de rajouter des colonnes et de rentrer toutes le données.
Avec mes remerciements anticipés,
Amicalement
Noel
Bonjour,
Une solution à base de formules matricielles :
Ton adresse en A1
En B1 :
=GAUCHE(A1;EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("1:"&NBCAR(A1)));5)*1);0)-1)à valider par CTRL + MAJ + ENTREE
EN C1 :
=STXT(A1;EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("1:"&NBCAR(A1)));5)*1);0);5)à valider par CTRL + MAJ + ENTREE
EN D1 :
=STXT(A1;EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("1:"&NBCAR(A1)));5)*1);0)+6;99)à valider par CTRL + MAJ + ENTREE
Le principe consiste à trouver l'emplacement d'une chaine de 5 caractères numériques consécutifs (le code postal)
Je te laisse tester
@+
Re
Mon cher Thibo,
C'est génial.
Maintenant si je veux que le CP et la ville se retrouvent dans la même cellule que faut-il faire?
Pourquoi la différence
=STXT(A1;EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("1:"&NBCAR(A1)));5)*1);0);5)
=STXT(A1;EQUIV(VRAI;ESTNUM(STXT(SUBSTITUE(A1;" ";"µ");LIGNE(INDIRECT("1:"&NBCAR(A1)));5)*1);0)+6;99)
;5) et +6;99)
Si je demande cela c'est pour mon apprentissage. Il faut que j'arrive à comprendre les astuces d'Excel.
Merci
de ton aide
Amicalement
Noel
-- Lun Jan 04, 2010 8:22 pm --
Re
Thibo,
J'ai trouvé la solution tout seul. Le chiffre +6 c'est la sixième lettre après le CP.
En mettant simplement 99 en enlevant le +6 cela me donne le CP et la Ville
Je pense que le 99 c'est le nombre de lettre après le CP.
Pourras-tu me le confirmer.
@+
Amicalement
Noel
re,
Je te confirme que le 99, c'est pour la ville.
Il y a peu de chances (du moins en France), que le nom d'une ville dépasse les 99 caractères.
Si nécessité, tu peux remplacer 99 par 9^9 qui nous donne 387420489
Voilou
@+
Bonjour à tous,
Merci Thibo de ton aide.
Je ne sais quoi rajouter à toutes ces questions posées?
Il y en certainement d'autres et voir beaucoup car j'ai lu en diagonale toutes les questions qui se posent sur ce forum et je pense qu'une majorité est résolue.
Tout ça à des forumeurs qui comme toi toujours à la recherche de surpasser les difficultés
Amicalement
Noel