Sauvegarde ma feuille facture

Bonjour à tous,

Je sais le sujet à déjà été traité. J'ai un dossier "Facturation" et dedans un sous dossier "Fact" ou je souhaite ma sauvegarde. ci dessous mon code :

Option Explicit

Sub SauveFac()
Dim Nom As String
If (Range("J14") = "") Or (Range("K7") = "") Then
    MsgBox "Le nom du client n'est pas renseigné" & Chr(10) & "ou le numéro de facture n'est pas saisi" _
    & Chr(10) & Chr(10) & "Arrêt de la macro"
    End
End If
Application.ScreenUpdating = False
Nom = Range("J14") & "_" & Range("K9") & "_" & Range("K7")

Sheets("Factures").Activate
ActiveSheet.Copy
ChDir ThisWorkbook.Path

'Chemin = ThisWorkbook.Path & "\"
'ActiveWorkbook.SaveAs Filename:=Chemin & Nom & ".xlsx"

ActiveWindow.Close
Application.ScreenUpdating = True
End Sub

Elle bug à chemin je joint mon fichier. Pourriez vous m'aider SVP

Encore moi, serait -il aussi possible de ne pas sauvegarder les 3 boutons ?

Bonjour,

C'est votre date qui provoque le bug.

Sub SauveFac()

Dim Chemin As String, Nom As String, MaDate As String
Dim I As Integer

    With ThisWorkbook
         ChDir .Path
         Chemin = ThisWorkbook.Path & "\"
         With Range("DateFacture")
              MaDate = Format(Day(.Value), "00") & "-" & Format(Month(.Value), "00") & "-" & Year(.Value)
         End With
    End With

    If Range("NomClient") = "" Or Range("NumeroFacture") = "" Then
        MsgBox "Le nom du client n'est pas renseigné" & Chr(10) & "ou le numéro de facture n'est pas saisi" _
        & Chr(10) & Chr(10) & "Arrêt de la macro"
        Exit Sub
    End If

    Application.ScreenUpdating = False
    Nom = Range("NomClient") & "_" & MaDate & "_" & Range("NumeroFacture")
    Debug.Print Nom
    Sheets("Factures").Copy

    With ActiveWorkbook
         With Sheets(1)
              For I = .Shapes.Count To 1 Step -1
                    With .Shapes(I)
                         Select Case .Name
                                Case "Image 10", "Rectangle 1", "Rectangle 2"
                                     .Delete
                         End Select
                    End With
              Next I
         End With
         .SaveAs Filename:=Chemin & Nom & ".xlsx"
         .Close
    End With

    Application.ScreenUpdating = True

End Sub

Bonjour Eric,

Elle beug à With Range("DateFacture") il faut peut etre que je saisisse ma cellule c'est K9,.

pareil ici If Range("NomClient") = "" Or Range("NumeroFacture") = "" Then

j'ai remplacé Nom le numéro par les cellules concernée, il n'a pas sauvegardé dans le sous répertoire "Fact", et voilà ce que j'ai. pas le nom et pas la date, Merci

Voir le fichier joint, à vous de modifier le répertoire de destination.

Merci Eric,

Bonne Journée