Sauvegarde d'un classeur

Bonjour,

J'ai ce code qui fonctionne bien lors de la sauvegarde de feuilles d'un classeur mais l'ennui est si le fichier existe déjà et que je clique sur non pour arréter la sauvegarde ou j'ai un message d'erreur.

Private Sub Commandbutton1_Click()

Application.ScreenUpdating = False

Sheets(Array("Feuil1", "Feuil3")).Copy

With ActiveWorkbook
    ActiveWorkbook.SaveAs "BDD-SAVE" & Format(Now, "yyyy-mm-dd")
    .Close
End With

MsgBox "La base de données a été exporté avec succès"

Application.ScreenUpdating = True

End Sub

Comment puis je éviter ce problème ?

Bonjour

Peux tu tester ceci ?

Private Sub Commandbutton1_Click()
  Dim Fichier As String

  Application.ScreenUpdating = False
  Fichier = "BDD-SAVE" & Format(Now, "yyyy-mm-dd") & ".xls"
  If Dir(Fichier) <> "" Then
    If MsgBox("Fichier " & Fichier & " déjà présent" & vbCr & "On le remplace ? ", vbCritical + vbYesNo + vbDefaultButton2, "Fichier existant") <> vbYes Then Exit Sub
  End If

  Sheets(Array("Feuil1", "Feuil3")).Copy
  Application.DisplayAlerts = False
  With ActiveWorkbook
    ActiveWorkbook.SaveAs Fichier
    .Close
  End With
  Application.DisplayAlerts = True

  MsgBox "La base de données a été exporté avec succès"

  Application.ScreenUpdating = True

End Sub

Je viens de trouver cette solution grâce à un des post en dessous

Private Sub Commandbutton1_Click()

Dim chemin, fichier As String

chemin = ThisWorkbook.Path
fichier = "BDD-SAVE" & Format(Now, "yyyy-mm-dd") & ".xls"

Application.ScreenUpdating = False

If Dir(chemin & "\" & fichier) <> "" Then
    If MsgBox("Un fichier portant le nom " & fichier & " existe déjà" & _
          vbCr & "Souhaitez vous le remplacer ? ", vbCritical + vbYesNo, "ATTENTION") <> vbYes Then Exit Sub
End If

Application.DisplayAlerts = False

Sheets(Array("Feuil1", "Feuil3")).Copy

With ActiveWorkbook
    ActiveWorkbook.SaveAs Filename:=chemin & "\" & fichier
    .Close
End With

MsgBox "Les bases de données ont été exporté avec succès"

With Application
    .DisplayAlerts = True
    .ScreenUpdating = True
End With

End Sub

Merci Banzai,

Je ne trouvais pas dans le forum et après avoir posté j'ai vu que tu avais déjà traité cette demande dans un sujet similaire ici.