Resultat dans même cellule

Bonjour, je débute et ai besoin d'aide afin de savoir s'il est possible, et comment entrée une valeur dans une cellule et obtenir un résultat en % dans cette même cellule. A la place de la valeur entrée ...biensure.

Merci d'avance.

Bonjour ticino et bienvenu,

Tu entres ta valeur normalement ( par exemple 0.8 ) dans ta cellule puis tu fais clic droit -> 'Format de cellule' et dans l'onglet 'Nombre' tu choisis le format 'Pourcentage'.

A+

Bonjour et bienvenu, Salut vba-new,

Sélectionne ta ou tes cellules, Ruban "Accueil" et partie "Nombre" clique sur l'outil "Style de pourcentage (signe %)" et saisi ton chiffre normalement.

Merci d'avoir répondu. Mais je me suis mal exprimé. Voici un exemple de ce que je voudrais faire. Je voudrais avoir le pourcentage de production que j'ai ds ma journée avec une machine qui tourne au maxi a 10000 pieces /jour. Ma prod de la journée a été de 7500. Je voudrais entrée 7500 ds une cellule et que le calcul 7500/10000*100 ce fasse tout seul et que le résultat prenne la place des 7500 précédemment entrée. J'espère avoir été plus clair et encore merci pour votre aide.

Salut ticino, raja,

Ok, c'est plus compréhensible maintenant.

Dans ce cas, pourquoi ne pas ajouter une colonne qui fera ton calcul?

Ex : en A2, tu entres 7500 et en B2 tu mets la formule "=A2/10000*100"

Dis moi si cela te va.

Oui, j'avais aussi pensé a cette solution, mais je n'ai plus de place sur la page pour ajouter cette colonne. Et pour tout dire, j' ai parié que c'était surement possible... Je pourrais rajouter cette colonne a coté et ne pas la mettre dans la zone d'impression mais c'est bien le pb exposé que je voudrais résoudre, mais ce n'est sans doute pas facile. Merci.

Bonjour,

Voici une solution en VBA.

Dans la feuille Feuil1, saisir une valeur en colonne A et la valeur saisie est remplacée par le résultat de la formule : valeur * 10000 / 100

Fichier

Bonjour Readi, cette solution me convient parfaitement. Peux-tu m'expliquer comment faire cela moi-même ou sais-tu où je peux trouver le tuto. Merci encore.

Bonjour,

Pour ajouter le code VBA dans ton classeur :

1/ Appuyer sur ALT+F11

2/ Dans la partie gauche de la fenêtre de projets, double clic sur la feuille dans laquelle le traitement doit être réalisé

3/ Dans la partie droite de la fenêtre, coller le code ci-dessous :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Intersect(Range("A:A"), Target) Is Nothing Then Exit Sub

    Application.EnableEvents = False

    If IsNumeric(Target.Value) Then Target.Value = Target.Value / 10000 * 100

    Application.EnableEvents = True
End Sub

4/ Dans le code, remplacer "A:A" par la colonne dans laquelle s'effectue la saisie

5/ Fermer la fenêtre

Merci beaucoup, c'est exactement ce qu'il me faut. Au risque d'abuser de votre gentillesse pouvez-vous me dire ce qu'il faut rajouter pour arrondir le résultat a l'entier sup. Merci

PS: j'ai essayé seul mais pas moyen...

Bonjour,

Fonction Plafond:

If IsNumeric(Target.Value) Then Target.Value = WorksheetFunction.Ceiling(Target.Value / 10000 * 100, 1)

Amicalement

Claude.

Bonjour, Salut à tous,

Une autre solution par la fonction ARRONDI.SUP :

If IsNumeric(Target.Value) Then Target.Value = WorksheetFunction.RoundUp(Target.Value / 10000 * 100, 0)

PS : je n'ai pas compris pourquoi une division par 10000 et une multiplication par 100, je dois avoir loupé quelque chose.

Bonjour,

Pour arrondir à l'entier supérieur :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Intersect(Range("A:A"), Target) Is Nothing Then Exit Sub

    Application.EnableEvents = False

    If IsNumeric(Target.Value) Then Target.Value = Application.WorksheetFunction.RoundUp(Target.Value / 10000 * 100, 0)

    Application.EnableEvents = True
End Sub

re,

C'est peut-être çà que souhaite notre ami,

If IsNumeric(Target.Value) Then Target.Value = WorksheetFunction.RoundUp(Target.Value / 100, 3)

Claude.

Merci les amis, vous êtes trop fort. Ca marche super même si j'ai pas tout compris. A+

re,

Nous aimerions bien savoir quelle formule tu as retenu.

et n'oublie pas la petite formalité:

en étant connecté.

Amicalement

Claude.

Salut a tous, j'ai retenu la reponse de Readi avec qui j'avais commencé. Mais merci a tous ceux qui ont fait les efforts pour m'aider. C'est un peu trop compliquer pour moi compte tenu de mes connaissances actuelles sur Excel, mais je vais essayer de m'améliorer. Mon problème est résolu mais il me manque une ''bricole'' pour que ce soit parfait. J'ai donc le résultat d'un pourcentage mais pas le sigle % qui s'affiche ds ma cellule car si je mets la mise en forme %, la macro ne s'exécute plus. Merci.

Bonjour à tous,

en relisant ton 1er message, tu tape 7500, çà t'affiche 75%

tu mets toute ta colonne au format % sans décimale,

et tu mets ce code comme expliqué précédemment

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
    If Not Application.Intersect(Target, Range("a:a")) Is Nothing Then
        Application.EnableEvents = False
        If IsNumeric(Target.Value) Then Target.Value = WorksheetFunction.RoundUp(Target.Value / 100, 2)
        Application.EnableEvents = True
    End If
End Sub

Amicalement

Claude.

édit: arrondi formule modifié

Bonjour

sans avoir à mettre tes cellules au format %

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Intersect(Range("A:A"), Target) Is Nothing Then Exit Sub
    Application.EnableEvents = False
    If IsNumeric(Target.Value) Then Target.Value = Application.WorksheetFunction.RoundUp(Target.Value / 10000 * 100, 0) & " %"
    Application.EnableEvents = True
End Sub

Cordialement

re,

Salut Amadéus,

ce dernier code ne permet pas de changer la valeur saisie, (affiche 1%)

Edit Amadéus: Bonjour Claude. OK, je m'étais trompé de recopie, c'est réparé

Bonne journée

Claude.