Reprise valeur combobox

Bonjour,

Je cherche à récupérer la valeur de 2 combobox. Avec le code ci-dessous, la valeur de combobox1 se reprend bien mais pas pour la 2ème.

Pourriez-vous m'aider ?

Par avance merci

Option Explicit

Private Sub UserForm_Initialize()
ComboBox1.Clear
ComboBox1.List = Application.Transpose(Range("titre"))
ComboBox2.Clear

End Sub

Private Sub ComboBox1_Change() 'Combobox département
If ComboBox1.Value = "" Then Exit Sub
ComboBox2.Clear

Dim NomRange As String
NomRange = CaracSpec(ComboBox1.Value)
If NomDefini(NomRange) Then
    ComboBox2.List = Application.Transpose(Range(NomRange))

End If

Range("H1").Value = ComboBox1.Value
Range("H2").Value = ComboBox2.Value
End Sub

Function NomDefini(Nom As String) As Boolean
Dim Noms As Name
NomDefini = False
For Each Noms In ThisWorkbook.Names
    If Noms.Name = Nom Then NomDefini = True: Exit Function
Next Noms
End Function

Function CaracSpec(Nom As String) As String
CaracSpec = Replace(Nom, " ", "_")
CaracSpec = Replace(CaracSpec, "-", "_")
End Function

Je remonte le sujet^^

Bonsoir,

il me semblé que votre code devrait être ainsi :

Private Sub ComboBox1_Change() 'Combobox département
    If ComboBox1.Value = "" Then Exit Sub
    ComboBox2.Clear

    Dim NomRange As String
    NomRange = CaracSpec(ComboBox1.Value)
    If NomDefini(NomRange) Then
        ComboBox2.List = Application.Transpose(Range(NomRange))
    End If

    ActiveSheet.Range("H1").Value = ComboBox1.Value
End Sub

Private Sub ComboBox2_Change()
    If ComboBox2.Value = "" Then Exit Sub

    ActiveSheet.Range("H2").Value = ComboBox2.Value
End Sub

Merci Thev,

Du coup, j'ai fait autrement.

Private Sub CommandButton1_Click()
Range("H1").Value = ComboBox1.Value
Range("H2").Value = ComboBox2.Value
Unload Me
End Sub

Et ça à l'air de fonctionner correctement.