Recuperation caractères soulignés dans une cellule

Bonjour,

J'ai un tableau qui a des cellules dont ses caractères sont partiellement soulignés; du style "xxx. xxx xxx xxx". J'aimerai faire une procedure en vba qui ajoute une lettre avant et après ces caractères soulignés. Pour info, le nombre de caractère souligné et non souligné varie.

Pouvez vous m'aider svp?

bonsoir,

voici une fonction personnalisée.

exemple d'appel dans une cellule excel

=enclos(A1;"*")

si A1 contient www.www www www

le résultat sera *www.www* www www

Function enclos(r As Range, spcar As String) As String
'fonction qui ajoute un string "spcar" avant et après une séquence de caractères soulignés dans la cellule "r"
sw = 0
For i = 1 To Len(r)
If IsUnderLined(r, i) Then
 If sw = 0 Then
  sw = 1
  s = s & spcar
 End If
Else
 If sw = 1 Then
  sw = 0
  s = s & spcar
 End If
End If
s = s & Mid(r, i, 1)
Next i
If sw = 1 Then s = s & spcar

enclos = s
End Function

Function IsUnderLined(r As Range, pos) As Boolean
'fonction qui indique si le caractère à la position "pos" d'une cellule "r" est souligné (vrai) ou non (faux)

If r.Characters(pos, 1).Font.Underline <> xlUnderlineStyleNone Then IsUnderLined = True Else IsUnderLined = False
End Function

Merci beaucoup! C est tout ce dont j avais besoin, la rapidite de reponse en plus.

Les belges sont toujours les plus sympa