RechercheV_Index_Equiv
Bonjour à tous
Je cherche la bonne formule pour avoir les valeurs (CA, CIO, Taux 1, etc) de chaque semaine?
Ci-joint un exemple.
Merci beaucoup
Salut Mahdiest !
Ni RechercheV, ni Index, ni Equivpour moi
Une proposition de formule qui mixe un Indirect() et un Sommeprod().
Les explications (qui sont également sur le fichier joint) :
J'ai recréé en colonne G le nom de chaque onglet en fonction de la date de la colonne A (avec la fonction NO.SMEMAINE());
Je me suis servie de ces noms d'onglet pour utiliser la fonction "Indirect" qui est une fonction qui permet de pointer vers un nom d'onglet dynamique (donc pour schématiser : au lieu de chercher dans l'onglet "S1" je cherche dans l'onglet "Indirect(G4)");
Ensuite c'est un sommeprod qui va chercher le numéro de client, la date, et l'intitulé (CA, CIO, etc…)
Les modifs que j'ai dû faire sur tes onglets pour que ça marche :
- ajouter la colonne G de l'onglet de synthèse
- défusionner les cellules où il y a la date et faire apparaître la date dans chaque cellule
Conseil qui n'engage que moi : Toujours avoir en tête qu'il faut éviter les fusions de cellules. Certes c'est joli mais dès qu'on veut exploiter les données, mettre des formules etc, la fusion c'est le diable !
Merci beaucoup Gaz0line
C'est parfait!
Bonjour à tous.
J'ai actualiser le fichier test mais il m'affiche erreur dans la formule (SOMMEPRO)
Merci de me corriger la formule.
Bonjour,
en présentant tes données autrement, un seul onglet suffit et une TCD pour tes totaux
P.
Merci patrick1957 pour la réactivité.
Toutefois je n'ai pas qu'une seule semaine (S26) mais de Semaine 1 à semaine, pour cette raison j'ai besoin de la feuille "Synthèse" qui regroupe toutes les semaines.
Merci bien de vérifier l'erreur VALEUR! au niveau de la feuille "Synthèse"
re,
Toutefois je n'ai pas qu'une seule semaine (S26) mais de Semaine 1 à semaine, pour cette raison j'ai besoin de la feuille "Synthèse" qui regroupe toutes les semaines.
ça ne change rien, si tu as des dates qui s'incrémentent, les semaines aussi et le tcd reste valable ...
d'autre part le tableau de base présenté ainsi est plus lisible et tu sais modifier toi même le tcd sans être un grand spécialiste des formules
P.
Merci encore
C'est une bonne idée
Salut !
Ton adaptation était correcte (mis à part une plage qui n'était pas bonne mais ce n'était pas ça qui te donnait "#VALEUR).
Le problème venait du fait que tes cellules vides bloquaient la formule dans ton tableau. en mettant un zéro dans tes cellules vides, ou en faisant suppr dans tes cellules vides, ça fonctionne.
Merci beaucoup pour la réactivité
Bonjour,
Pourquoi lorsque j'ajoute une ligne supplémentaire (Client 4) et je change la plage au niveau de la formule il m'affiche #N/A:
=SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE43")))
Merci d'avance
Salut !
Parce qu'il faut aussi agrandir ta plage de somme finale :
=SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE43")))
Doit devenir :
=SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE44")))
Sinon c'est incohérent et donc #N/A
Merci pour la bonne réponse
Y-a-t-il une possibilité d'ajouter la fonction (SI ERREUR) dans la formule pour éviter d'afficher #REF! en cas d'inexistence de données.
Si Oui comment faire?
Merci d'avance
Re !
=SI(ESTERREUR(SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE44"))))
;"";
SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE44"))))
Ou bien en moins long :
=SIERREUR(SOMMEPROD((INDIRECT($B4&"!G41:G44")=Synthèse!$D4)
*(INDIRECT($B4&"!H39:AE39")=Synthèse!E$3)
*(INDIRECT($B4&"!H40:AE40")=Synthèse!$C4)
*(INDIRECT($B4&"!H41:AE44")));0)
Merci beaucoup Gaz0line
De rien Mahdiest