Rechercher une valeur

Bonjour

J'ai un fichier dans lequel je cherche toutes les occurrences d'une valeur dans la colonne C.

Actuellement j'affiche un message avec l'adresse des cellules trouvées mais je souhaiterais pouvoir remplacer ces adresses par la valeur de la cellule situé en colonne A.

Voici mon code actuel :

Sub TEST()
Dim CelluleNc As Range
Dim AdresseNc As String
Dim Resultat As String
Dim Dern_ligne As String
Dim Nombre_de_tests_non_conformes As Boolean

Dern_ligne = Range("B" & Rows.Count).End(xlUp).Row
Zone_test = "C1:C" & (Dern_ligne)

    'cherche "NC" dans la colonne C
    Set CelluleNc = Range(Zone_test).Find(What:="NC", LookIn:=xlValues, LookAt:=xlWhole)
        'si "NC" est trouvé
        If Not CelluleNc Is Nothing Then
            'on mémorise l'adresse de la première occurence trouvée
            AdresseNc = CelluleNc.Address
            Do
                'on mémorise l'adresse de la ligne
                Resultat = Resultat & Chr(10) & CelluleNc.Address(0, 0)
                'on continue la recherche
                Set CelluleNc = Range("C1:C" & Dern_ligne).FindNext(CelluleNc)
            'tant qu'on trouve "NC" et que l'occurence trouvée est différente de la première occurence trouvée
            Loop While Not CelluleNc Is Nothing And CelluleNc.Address <> AdresseNc
            'affichage du résultat
            MsgBox "NON CONFORMITÉS DÉCLARÉES ICI :" & Chr(10) & Resultat
            Nombre_de_tests_non_conformes = True
        Else:
            'MsgBox "PAS DE NON CONFORMITÉS"
            Nombre_de_tests_non_conformes = False
        End If
End Sub

Donc à la place de

CelluleNc.Address(0, 0)

je souhaiterai avoir le contenu de la cellule située en A

Je joint mon fichier de test.

Merci pour votre aide.

Bonsoir Scoprdragon, bonsoir le forum,

Essaie comme ça :

Resultat = Resultat & Chr(10) & CelluleNc.Offset(0, -2).Value

Merci c'est exactement ça