Recherche formule
Bonjour
J'ai une liste de Code postal, département et région.
En partant de la région je recherche tous les départemnts qui font partie de la région.
Ex; Région du Limousin = Creuse, Haute-Vienne et Correze
Pour illustrer ma demande, je joins un fichier
Je vous remercie de votre aide qui sera utile pour résoudre mon problème.
Cordialement
Max
Bonjour, la formule à utiliser peut-être la suivante
{=SI(LIGNES($1:1)<=NB.SI(Départements!$D$2:$D$97;Feuil1!$F$13);INDEX(Départements!$C$2:$C$97;PETITE.VALEUR(SI(Départements!$D$2:$D$97=Feuil1!$F$13;LIGNE(INDIRECT("1:"&LIGNES(Départements!$C$2:$C$97))));LIGNES($1:1)));"")}Attention c'est une formule matricielle qui doit être validée par Ctrl+MAJ+ENTER
En nommant les plages de recherche et de valeurs elle serait plus facile à lire.
Bonjour Robjam
Je te remercie de ta formule . Tu me dit que en nommant les plages de recherche et de valeurs elle serait plus facile à lire.
Pourrez tu me faire un exemple sa serez sympa ?
Merci et bonne journée
Max
Re
Avec plages nommées
{=SI(LIGNES($1:1)<=NB.SI(Régions;Critère);INDEX(Départements;PETITE.VALEUR(SI(Régions=Critère;LIGNE(INDIRECT("1:"&LIGNES(Départements))));LIGNES($1:1)));"")}Plages nommées :
Régions =Plage de recherche = Département!$D$2:$D:$97
Départements = Plage de valeurs = Départements!$C$2:$C$97
Critère = Nom de la région = Feuil1!$F$13
Re,
Je te remercie c'est vrai que la lecture est plus clair.
Si je peux abuser j'aimerais faire le contraire, Je m'explique
Sur le même fichier et la même feuille a la colonne E
En partant de ces départements
Je recherche les Code postaux qui lui appartiennent
Je te remercie de ton aide qui sera utile pour résoudre mon problème.
Pour illustrer ma demande, je joins un fichier
Cordialement
Max
Re,
Avec les fonctions INDEX et EQUIV on y arrive
Formule à mettre en E19 et à tirer vers le bas
=SI($F19<>"";INDEX(Départements!$B$2:$C$97;EQUIV(Feuil1!$F19;Départements;0);1);"")