Recherche en surbrillance qui perd sa couleur de fond ensuite

Bonjour,

Je vous explique mon souci. J'ai une macro qui permet d'afficher le fonds d'une cellule en couleur lors d'une recherche (CTRL+F). Elle fonctionne très bien. Le seul souci est que lorsque qu'un résultat est une cellule ayant une couleur de fond, la couleur disparaît lorsque l'on quitte la cellule. Quelqu'un aurait une idée pour arranger cela?

Voici ma macro:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Static AncAdress As String
    If Target.Count > 1 Then Exit Sub
    If AncAdress <> "" Then 'remettre en normal
        Range(AncAdress).Interior.ColorIndex = xlNone
        Range(AncAdress).Font.ColorIndex = 0
    End If
    Target.Font.ColorIndex = 1
    Target.Interior.ColorIndex = 34
    Target.Interior.Pattern = xlSolid
    AncAdress = Target.Address
End Sub

Merci d'avance et belle journée!

Bonjour,

ajoute quelques variables pour mémoriser l'info nécessaire

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static AncAdress As String
    Static AncCouleurFont, AncCouleurInterior
    If Target.Count > 1 Then Exit Sub
    If AncAdress <> "" Then 'remettre en normal
        Range(AncAdress).Interior.Color = AncCouleurInterior
        Range(AncAdress).Font.Color = AncCouleurFont
    End If
    AncCouleurInterior = Target.Interior.Color
    AncCouleurFont = Target.Font.Color
    Target.Font.ColorIndex = 1
    Target.Interior.ColorIndex = 34
    Target.Interior.Pattern = xlSolid
    AncAdress = Target.Address
End Sub

ça fonction à la perfection. Merci infiniment pour l'aide!

Je passe le sujet en résolu!