Probleme selection cellule VBA

Bonjour,

n'ayant que des connaissances tres limité en vba, je voudrais réaliser le travail suivant:

mon boulot est de rentrer la désignation d'article sous excel dans la colonne A et le code de l'article dans la colonne B. Cette tâche étant fastidieuse , j'ai voulu faire en sorte que lorsque je rentre un article déja saisie aupravant , en appuyant sur un bouton , le code se mette automatiquement.Pour cela , j'ai ecrise le code suivant:

"Dim l As Integer, i As Integer

Private Sub CBcopier_click()

l = Selection.Row

For i = 1 To l - 1

If Cells(l, 1).Value = Cells(i, 1).Value Then

Cells(l, 2).Value = Cells(i, 2).Value

End If

Next i

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

End Sub"

Le probleme que je rencontre maintenant , c'est qu'il faut que je selectionne un article , cliquez sur le bouton et ainsi de suite pour chaque article ( et ca n'augmente guere mon gain de temps).

La ou je bloque c que je ne sais pas comment faire pour réaliser l'operation pour plusieur article d'un coup sachant que je rentre a la suite les articles et que j'en saisie environ 15 d'un coup.

Je sais pas si c tres claire , mas si vous avez une réponse a m'apporter , ca serait cool

Merci

Bonjour

Un code à placer dans le code de la feuille à la place de celui que tu as

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cel As Range

  If Not Intersect(Columns(1), Target) Is Nothing And Target.Count = 1 Then
  If Target.Row = 1 Then Exit Sub
    Set Cel = Range("A1:A" & Target.Row - 1).Find(what:=Target, LookIn:=xlValues, lookat:=xlWhole)
    If Not Cel Is Nothing Then
      Application.EnableEvents = False
      Target.Offset(0, 1) = Cel.Offset(0, 1)
      Application.EnableEvents = True
    End If
  End If
End Sub

En cas de plantage (Rare car juste 1 instruction)

Il faudra exécuter cette macro pour rétablir la gestion des évènements

Sub Ret()

Application.EnableEvents = True

End Sub

MERCI C TROP TOP !!!!!!!!