Problème pour faire une formule
Bonjour à tous,
Voilà j'ai un problème sur excel. Je souhaite mettre en place une formule.
J'ai dans les cases H82, I82 des dates d'inscrites. La première représente le délai (la date butoire) pour mettre en place une action et la seconde représente la date effective à laquelle l'action a été mise en place.
J'ai en case L1 (case fixe) la date du jour.
Je cherche donc à calculer le nombre de jour de retard pris entre la date butoire pour réaliser l'action (case H82) et la date du jour.
Ca j'ai réussi à le faire.
Mais ce que je veux, c'est en même temps pouvoir revenir en arrière (rétroactivité) et de savoir les nombres de jours de retard (situé par ex dans la case L82), si je change la date du jour avec une date d'il y a 3 mois.
Concrètement, j'aimerai que si la case I82 est vide et que la case H82 a une date inférieure à celle indiquée dans la case L1, il soit affiché dans la case L82 la différence entre la date du jour (case L1) et la date butoire (H82).
Si la case I82 est vide et que la case H82 a une date supérieure à celle indiqué dans la case L1, il soit affiché 0 dans la case L82.
Si la case I82 a une date inférieure à celle indiqué dans la case L1, il soit affiché 0 dans la case L82.
Si la case I82 à une date supérieur à celle indiqué dans la case L1, il soit affiché dans la case L82 la différence entre la date du jour (case L1) et la date butoire (H82).
J'ai donc mis cette formule :
=(SI(OU(I82=0;I82>$L$1>0);$L$1-H82;0))*OU(SI(OU(H82>$L$1;$L$1>I82>H82>0);0;$L$1-H82))
J'ai aussi essayé sous d'autres formes, mais a chaque, il y a une ides 4 ndications éronnées.
J'espère avoir été clair est que vous pourriez me venir en aide.
Merci.
Bonjour et bienvenu sur le forum,
Essaye la formule suivante sur la cellule L82 : =SI(I82="";SI(H82>L1;H82-L1;"");SI(I82>H82;I82-H82)). La cellule L82 est en format standard.
Cdlt,
Raja a écrit :Bonjour et bienvenu sur le forum,
Essaye la formule suivante sur la cellule L82 : =SI(I82="";SI(H82>L1;H82-L1;"");SI(I82>H82;I82-H82)). La cellule L82 est en format standard.
Cdlt,
Merci pour ta réponse. J'ai donc utilisé ta formule, et j'ai remis dans le bon sens les numéros de cases à l'intérieur et ça donne donc ça :
=SI(I82="";SI(H82<L1;L1-H82;"");SI(I82>L1;L1-H82;""))
A première vue ça fonctionne.
Je te remercie vraiment pour ton aide.
Alors maintenant, j'aimerai si possible un nouvel ajout à la formule.
C'est à dire, quand la case H82 (date butoire) est vide, avec la formule, cela m'indique le chiffre 39513. Excel doit surement faire L1-H82 avec pour L1 la date du jour et pour H82 comme il n'y a pas de date il doit prendre le 01/01/1900.
Bref, je voudrais que dans ce cas-là, il n'y ai rien d'indiqué. Comme faire ?
Merci d'avance.
Ajoute la condition pour l'espace vide et ce doit être la première condition vérifiée.
=SI(H82="";"";SI(I82="";SI(H82<L1;L1-H82;"");SI(I82>L1;L1-H82;"")))
Voilà.
Bonsoir
à ta formule
=SI(I82="";SI(H82<L1;L1-H82;"");SI(I82>L1;L1-H82;""))
tu ajoutes ta nouvelle condition
=SI(ESTVIDE(H82);"";SI(I82="";SI(H82<L1;L1-H82;"");SI(I82>L1;L1-H82;"")))
ou
=SI(H82="";"";SI(I82="";SI(H82<L1;L1-H82;"");SI(I82>L1;L1-H82;"")))
Cordialement
Merci à vous deux, ça fonctionne
Je remarque que l'ordre des conditions à bcp d'importance. Je ne pensais pas à ce point.
C'est surement là que venait mes erreurs, je mettais les conditions dans l'ordre qu'elles me venaient en tête.
Y'a t'il des règles de bases à connaître pour l'ordre des conditions ?
Oui. L'ordre de priorité.
Si par exemple, tu commets une erreur de formulation et que tu écris 3 au lieu de 4 dans la 1re condition,
=SI(A1="";"";SI(A1>3;"Ok";SI(A1=4;"Pas ok";"Peu importe")))
Quand tu écriras 4, alors que tu veux "Pas ok", tu auras "Ok" parce que ta 1re condition est évaluée avant la 2e.
Merci pour cet éclairsissement
J'ai rajouté une condition à ma formule afin qu'elle couvre le fait que lorsque que la date butoire (H82) est supérieure à la date du jour (L1), il n'y ai rien d'indiqué dans la case.
La formule a l'air de fonctionner mais par contre contre excel me dit qu'elle est incohérente. Pourquoi ?
La voici :
=SI(H82="";"";SI(H82>$L$1;"";SI(I82="";SI(H82<$L$1;$L$1-H82;"");SI(I82>$L$1;$L$1-H82;""))))
Bonjour
Essaie
=SI(OU(H82="";H82>$L$1);"";SI(OU(ET(I82="";H82<L1);I82>L1);L1-H82;""))
Cordialement