Problème formule

Bonjour j'ai un code VBA qui a pour but de sélectionner une plage dans la feuil1 et de la copier vers la ligne suivante de la colonne A dans la feuil2. Tout fonctionne mais il y a une erreur à partir du set importplace, pouvez-vous m'aider merci !

Sub importdata()

  Dim i As Integer
  Dim a As Integer
  Dim alasuite As Integer
  Dim adv As Range
  Dim importplace As Range

  i = Cells(Rows.Count, 4).End(xlUp).Row
  a = Cells(Rows.Count, 1).End(xlUp).Row
  alasuite = Cells(Rows.Count, 1).End(xlUp).Row + 1

  Set adv = Sheets("Feuil1").Range("D20:D" & i)
  adv.Copy

  Set importplace = Sheets("Feuil2").Range("A8:A" & alasuite)
  importplace.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
End Sub

Il me copie à partir du la cellule A8 alors que je veut copier à la suite de la dernière valeur de la colonne A

Bonjour Floki, bonjour le forum,

Essaie comme ça :

Sub importdata()
Dim OS As Worksheet 'déclare la variable OS (Onglet Source)
Dim OD As Worksheet 'déclare la variable OD (Onglet Destination)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)

Set OS = Worksheets("Feuil1") 'définit l'onglet source OS
Set OD = Worksheets("Feuil2") 'définit l'onglet destination OD
DL = OS.Cells(Rows.Count, 4).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne D de l'onglet source
Set DEST = OD.Cells(Application.Rows.Count, "A").End(xlUp).Offset(1, 0) 'définit la cellule de destination DEST
OS.Range("D20:D" & DL).Copy 'copie la plage D20:D...
DEST.PasteSpecial Paste:=xlPasteValues 'colle les valeurs dans DEST
End Sub

Merci