Problème de virgule après le montant

bonsoir,

je suis perdu sur ce coup,

sur les classeurs ci-joint, 1 csv et 1 xlsm, j'ai le dernier montant qui est de 256,25, et sur l'autre il m'affiche que 256

surement dans le code qu'il y a une erreur

5telechargement.csv (367.00 Octets)
4compte.xlsm (40.09 Ko)

Bonjour Benoist,

1) pourquoi ce code tarabiscoté alors que celui-ci suffit

Private Sub Workbook_Open()
  Dim Wbk As Workbook
  Dim sPath As String, sFic As String
  Application.ScreenUpdating = False
  sPath = "C:\Users\33674\Desktop\"
  'sPath = ThisWorkbook.Path & "\"
  sFic = "telechargement.csv"
  Set Wbk = Workbooks.Open(sPath & sFic)
  Wbk.Sheets(1).Range("A6").Copy Destination:=ThisWorkbook.Sheets("compte mamie").Range("K6")
  Wbk.Close SaveChanges:=False
  Application.ScreenUpdating = True
End Sub

2) Le fichier ".csv" n'est pas fait correctement, 256 est séparé de 25
d'où vient-il ?

A+

Bonjour!

et merci de répondre, oui avec le nouveau code c'est pareil

pourquoi 256 est séparé de 25 !

et bien c'est un fichier qui vient d'une banque et c'est 256,25 euros

et j'ai pas dans dans le classeur compte les 25 cts

bonsoir!

je reformule ma demande, pour quoi je n'arrive pas à avoir les chiffres avec la virgule ,

dans mon fichier essai

je copie dans un fichier csv fermé sur bureau !

2telechargement.csv (148.00 Octets)
1essai.xlsm (30.09 Ko)

Bonsoir Benoist,

Essayes avec ceci ça à l'air de fonctionner

Private Sub Workbook_Open()
  Dim Wbk As Workbook
  Dim sPath As String, sFic As String
  Application.ScreenUpdating = False
  sPath = "C:\Users\33674\desktop\"
  sFic = "telechargement.csv"
  Workbooks.OpenText Filename:=sPath & sFic, Origin:=xlWindows, _
        StartRow:=1, DataType:=xlDelimited, Local:=True, Semicolon:=True
  Set Wbk = ActiveWorkbook
  Wbk.Sheets(1).Range("A6:a26").Copy Destination:=ThisWorkbook.Sheets("maison").Range("e2")
  Wbk.Close SaveChanges:=False
  Application.ScreenUpdating = True
End Sub

Ceci dit, c'est étrange car un fichier ".csv" avec séparateur point-virgule s'ouvre simplement avec Excel

A+

re

oui comme tu dit étrange,

mais toujours est-il que ça fonctionne parfaitement,

je l'adapte dans mon classeur et je te redit

mais ça me semble bon !

re,

voila c'est parfait

merci bien,

bonne soirée

Re

N'oublie pas

Rechercher des sujets similaires à "probleme virgule montant"