Probléme d'exporter les donner trie avec date déchéance

Bonjour,

Je suis en train de faire un tableau Excel pour faire la gestion des créances clientes avec date déchéance.

Je veux exporter les lignes des clients vers une autre feuil où il me fait le trie par moi

Exemple, je veux connaître tous les clients qui la date déchéance arrive par moi janvier, février .... ext

j'arrive pas a le faire

voici mon fichier

Bonjour Hassen et bienvenu, bonjour le forum,

Une seule ligne de données !... Pour tester un code il nous en faudrait plusieurs ! Tu le sauras pour la prochaine fois.

En piece jointe ton fichier modifié avec l'événementielle Change dans le composant VBA Feuil2(Feuil3) et le code ci-dessous :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim OS As Worksheet 'déclare la varaible OS (Onglet Source)
Dim DL As Integer 'déclare la varaible DL (Dernière Ligne)
Dim I As Integer 'déclare la varaible I (Incrément)
Dim DEST As Range 'déclare la varaible DEST (cellule de DESTination)

Application.ScreenUpdating = False 'masque les rafraîchissements d'écran
If Target.Address <> "$B$1" Then Exit Sub 'si le changement a lieu aillerus qu'en B1, sort de la procédure
Set OS = Worksheets("Feuil2") 'de'finit l'onglet source OS
Me.Range("A3").CurrentRegion.Offset(1, 0).Clear 'efface les anciennes données
If Target.Value = "" Then Exit Sub 'si B1 est effacée, sort de la procédure
DL = OS.Cells(Application.Rows.Count, "A").End(xlUp).Row 'de'finit la dernière ligne éditée DL de la colonne A de l'onglet OS
For I = 4 To DL 'boucle sur toutes les lignes I de 4 à DL
    If Format(OS.Cells(I, "G").Value, "mmmm") = Target.Value Then 'si le mois de la colonne G de la ligne de la boucle correspond au mois en B1
        Set DEST = Me.Cells(Application.Rows.Count, "A").End(xlUp).Offset(1, 0) 'définit la cellule de destination DEST
        OS.Rows(I).Copy DEST 'coopie la ligne I et la colle dans dest
    End If 'fin de la condition
Next I 'prochaine ligne de la boucle
Application.ScreenUpdating = True 'affiche les rafraîchissements d'écran
End Sub

Bonjour

Autre méthode

Avec un filtre piloté par VBA

Voir Code Feuil1 et Code Module

Code Feuil1

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Range("M3"), Target) Is Nothing And Target.Count = 1 Then
    Range("base").AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:= _
        Range("L3:L4"), Unique:=False
End If
End Sub

Code Module pour re-afficher tout

Sub affiche_tout()
On Error Resume Next
    ActiveSheet.ShowAllData
On Error GoTo 0
End Sub

Tu sélectionnes le mois dans la liste déroulante en M3

Pour tout re-afficher, tu cliques sur le bouton "Afficher tout"

Cordialement

Bonjour,

Tu n'as pas de factures à 30 jours, 30 jours fin de mois, etc...

Sinon, quelle est la version Excel utilisée ?

Cdlt.